psmile_ccompact_irreg2_real.F90

Go to the documentation of this file.

!-----------------------------------------------------------------------
! Copyright 2006-2010, NEC Europe Ltd., London, UK.
! All rights reserved. Use is subject to OASIS4 license terms.
!-----------------------------------------------------------------------
!BOP
!
! !ROUTINE: PSMILe_ccompact_irreg2_real
!
! !INTERFACE:

      subroutine psmile_ccompact_irreg2_real ( send_info,   &
               grid_valid_shape, shape, nb_corners,         &
               array_x, array_y, array_z,                   &
               extra_search, dest_size, nbr_cells_tot,      &
               source_cell_index,                           &
               neighcells, dest_x, dest_y, dest_z, ierror )
!
! !USES:
!
      use PRISM_constants
!
      use PSMILe, dummy_interface => PSMILe_ccompact_irreg2_real

      implicit none
!
! !INPUT PARAMETERS:
!
      Type (Send_information), Intent (InOut)  :: send_info
!
!     Structure containing the send information
!
      Integer, Intent (In)            :: grid_valid_shape (2, ndim_3d)

!     Specifies the valid block shape for the "ndim_3d"-dimensional block
!
      Integer, Intent (In)            :: shape (2, ndim_3d)
!
!     Shape of the array "array"
!
      Integer, Intent (In)            :: nb_corners
!
!     Number of corners in "array_x/y"
!
      Real, Intent (In)               :: array_x ( shape(1,1):shape(2,1), 
                                                   shape(1,2):shape(2,2), 
                                                   nb_corners )
      Real, Intent (In)               :: array_y ( shape(1,1):shape(2,1), 
                                                   shape(1,2):shape(2,2), 
                                                   nb_corners )
      Real, Intent (In)               :: array_z ( shape(1,3):shape(2,3) )
!
!     Arrays from which the compact list should be extracted
!
      Type (Extra_search_info), Intent (InOut) :: extra_search
!
!     Info's on global coordinates to be searched
!
      Integer, Intent (In)            :: dest_size
!
!     Size of destination arrays
!
      Integer, Intent (In)            :: nbr_cells_tot
!
!     Total number of source cells
!
      Integer, Intent (InOut)         :: source_cell_index (nbr_cells_tot)
!
!     Index of source cells
!
      Integer, Intent (InOut)         :: neighcells (nbr_cells_tot, nb_corners)
!
!
! !OUTPUT PARAMETERS:
!
      Real, Intent (Out)              :: dest_x (dest_size)
      Real, Intent (Out)              :: dest_y (dest_size)
      Real, Intent (Out)              :: dest_z (dest_size)
!
!     Output vectors of compact list
!
      Integer, Intent (Out)           :: ierror

!     Returns the error code of PSMILE_ccompact_irreg2_real;
!             ierror = 0 : No error
!             ierror > 0 : Severe error
!
! !LOCAL VARIABLES
!
!     ... for compact list
!
      Integer, Pointer                :: list_entries (:, :)
      Integer                         :: nbr_cells_loc
!
!     ... for extracting the compact list
!
      Integer                         :: i, k, l, n
      Integer                         :: ni, nij, nk, nij_loc
#if !defined DONT_USE_RESHAPE
      Integer                         :: dest_shape (1)
#endif
!
!     ... for globally searched data
!
      Integer                         :: dest_idx_off
      Integer                         :: stride, idx1, idx2
!
! !DESCRIPTION:
!
! Subroutine "PSMILe_ccompact_irreg2_real" extracts the data
! required from the 2-dimensional corner array "array" and stores the data in
! destination vector "dest_vector".
!
! !REVISION HISTORY:
!
!   Date      Programmer   Description
! ----------  ----------   -----------
! 03.07.21    R. Redler    created
!
!EOP
!----------------------------------------------------------------------
!
!  $Id: psmile_ccompact_irreg2_real.F90 2590 2010-09-23 15:56:33Z hanke $
!  $Author: hanke $
!
   Character(len=len_cvs_string), save :: mycvs = 
       '$Id: psmile_ccompact_irreg2_real.F90 2590 2010-09-23 15:56:33Z hanke $'
!
!----------------------------------------------------------------------
!
!  Initialization
!
#ifdef VERBOSE
      print 9990, trim(ch_id), send_info%send_entire_valid_shape

      call psmile_flushstd
#endif /* VERBOSE */
!
#ifdef PRISM_ASSERTION
      if (dest_size < send_info%n_list) then
         print *, trim(ch_id), 'dest_size, n_list', dest_size
         call psmile_assert (__FILE__, __LINE__, &
                             "dest_size is not sufficient")
      endif
#endif
!
      ierror = 0

      nbr_cells_loc = nbr_cells_tot - send_info%num2recv

      ! Initialization of output variables
      dest_x = -1
      dest_y = -1
      dest_z = -1
!
!------------------------------------------------------------------------
!     Store corners
!------------------------------------------------------------------------
!
!===> Special case: All points of grid shape
!
      if (send_info%send_entire_valid_shape) then
!
         ni  =      (grid_valid_shape (2, 1) - grid_valid_shape (1, 1) + 1)
         nij = ni * (grid_valid_shape (2, 2) - grid_valid_shape (1, 2) + 1) * nb_corners
         nk  =      (grid_valid_shape (2, 3) - grid_valid_shape (1, 3) + 1)
!
#ifdef PRISM_ASSERTION
         if (dest_size < nij * nk ) then
            print *, trim(ch_id), 'dest_size, nijk', dest_size, nij*nk
     
            call psmile_assert (__FILE__, __LINE__, &
                                "dest_size is not sufficient")
         endif
#endif

#ifdef DONT_USE_RESHAPE
         n = 0
!
         do l = 1, nb_corners
            do j = grid_valid_shape (1, 2), grid_valid_shape (2, 2)
               dest_x (n+1:n+ni) = &
                    array_x (grid_valid_shape (1,1):grid_valid_shape (2,1), j, l)
               dest_y (n+1:n+ni) = &
                    array_y (grid_valid_shape (1,1):grid_valid_shape (2,1), j, l)
               n = n + ni
            end do
         enddo
#else
         dest_shape (1) = nij

         dest_x (1:nij) = RESHAPE ( &
                           array_x(grid_valid_shape(1,1):grid_valid_shape(2,1),  &
                                   grid_valid_shape(1,2):grid_valid_shape(2,2),  &
                                   nb_corners), dest_shape)
         dest_y (1:nij) = RESHAPE ( &
                           array_y(grid_valid_shape(1,1):grid_valid_shape(2,1),  &
                                   grid_valid_shape(1,2):grid_valid_shape(2,2),  &
                                   nb_corners), dest_shape)
#endif
         dest_z (1:nij) = array_z(grid_valid_shape(1,3))
!
!===> ... Copy values for 3rd index
!         ! Das kann man auch noch besser machen !
!
         do k = 2, grid_valid_shape (2, 3) - grid_valid_shape (1, 3) + 1
            dest_x((k-1)*nij+1:k*nij) = dest_x(1:nij)
            dest_y((k-1)*nij+1:k*nij) = dest_y(1:nij)
            dest_z((k-1)*nij+1:k*nij) = array_z(k)
         end do

      else
!
!===> Get compact list
!
         list_entries => send_info%list_entries

         nij     = send_info%n_list
         nij_loc = nij - send_info%num2recv

#ifdef PRISM_ASSERTION
         if (.not. Associated (list_entries)) then
            call psmile_assert (__FILE__, __LINE__, &
                 "list_entries are not available")
         endif

!cdir vector
         do n = 1, nij_loc
            if ( list_entries(1, n) < shape (1,1) .or. &
                 list_entries(1, n) > shape (2,1) .or. &
                 list_entries(2, n) < shape (1,2) .or. &
                 list_entries(2, n) > shape (2,2)) exit
         end do

         if ( n < nij_loc ) then
            print *, 'n, list_entry, shape', n, list_entries(1, n), &
                 list_entries(2, n), shape
            call psmile_assert (__FILE__, __LINE__, &
                 "incorrect index in list_entries")
         endif
#endif

!cdir vector
         do l = 1, nb_corners
            do n = 1, nij_loc
               dest_x ((l-1)*nij+n) = array_x(list_entries(1, n), &
                                              list_entries(2, n),l)
               dest_y ((l-1)*nij+n) = array_y(list_entries(1, n), &
                                              list_entries(2, n),l)
               dest_z ((l-1)*nij+n) = array_z(list_entries(3, n))
            end do
         enddo

      endif

!------------------------------------------------------------------------
!     Create source cell index list
!------------------------------------------------------------------------

      do n = 2, nb_corners
         do i = 1, nbr_cells_loc
            neighcells (i,n) = neighcells (i,1) + (n-1) * nij
         end do
      enddo

      source_cell_index(:) = neighcells(:,1)
!
!-----------------------------------------------------------------------
!     Add cells found in global search.
!     The cells are added at the end of the buffer.
!-----------------------------------------------------------------------
!
      if ( send_info%num2recv > 0 ) then

         do n = 2, nb_corners
            do i = 1, send_info%num2recv
               neighcells (nbr_cells_loc+i,n) = &
               neighcells (nbr_cells_loc+i,1) + (n-1) * nij
            end do
         enddo

         ! calucalate offset for dest_*
         ! we write behind the data of the local process
         dest_idx_off = nij_loc

         do l = 1, extra_search%nrecv

            stride = nb_corners*send_info%len_sent(l)

            do k = 1, nb_corners
               do n = 1, send_info%len_sent(l)
                  idx1 = (k-1)*send_info%len_sent(l)+n
                  idx2 = stride + idx1

                  dest_x ((k-1)*nij+dest_idx_off+n) = extra_search%real_bufs(l)%vector(idx1)
                  dest_y ((k-1)*nij+dest_idx_off+n) = extra_search%real_bufs(l)%vector(idx2)
! Rene : vertical coordinate not clean yet !!
                  dest_z ((k-1)*nij+dest_idx_off+n) = array_z(1)

               end do
            enddo

            ! we do not want to overwrite the data just written
            dest_idx_off = dest_idx_off + send_info%len_sent(l)

            Deallocate (extra_search%real_bufs(l)%vector)

         enddo
      endif
!
!===> All done
!
#ifdef VERBOSE
      print 9980, trim(ch_id), ierror

      call psmile_flushstd
#endif /* VERBOSE */
!
!  Formats:
!
9990 format (1x, a, ': psmile_ccompact_irreg2_real: send_entire_valid', l2)
9980 format (1x, a, ': psmile_ccompact_irreg2_real: eof ierror = ', i8)

      end subroutine psmile_ccompact_irreg2_real