psmile_get_comp_handle.F90

Go to the documentation of this file.

!-----------------------------------------------------------------------
! Copyright 2006-2010, NEC Europe Ltd., London, UK.
! All rights reserved. Use is subject to OASIS4 license terms.
!-----------------------------------------------------------------------
!BOP
!
! !ROUTINE: PSMILe_Get_comp_handle
!
! !INTERFACE:

      subroutine psmile_get_comp_handle (comp_id, comp_name, ierror)
!
! !USES:
!
      use PRISM_constants
!
      use PSMILe, dummy_interface => PSMILe_Get_comp_handle

      implicit none
!
! !INPUT PARAMETERS:
!
      character (len=*), Intent(In)       :: comp_name

!     Name of the component
!
! !OUTPUT PARAMETERS:
!
      integer, Intent (Out)               :: comp_id

!     Returns the handle to the component information created.

      integer, Intent (Out)               :: ierror

!     Returns the error code of PRISM_Init;
!             ierror = 0 : No error
!             ierror > 0 : Severe error
!
!
! !LOCAL VARIABLES
!
      type (Component), Pointer :: New_Comps(:)

      integer             :: i
      integer             :: new_dim

      integer, parameter  :: nerrp = 2
      integer             :: ierrp (nerrp)
!
! !DESCRIPTION:
!
! Subroutine "PSMILe_Get_comp_handle" returns a handle to a model
! component.
!
!
! !REVISION HISTORY:
!
!   Date      Programmer    Description
! ----------  -----------   -----------
! 01.12.03    H. Ritzdorf   created
!
!EOP
!----------------------------------------------------------------------
!
! $Id: psmile_get_comp_handle.F90 2325 2010-04-21 15:00:07Z valcke $
! $Author: valcke $
!
   Character(len=len_cvs_string), save :: mycvs = 
       '$Id: psmile_get_comp_handle.F90 2325 2010-04-21 15:00:07Z valcke $'
!
!----------------------------------------------------------------------

#ifdef VERBOSE
      print *, trim(ch_id), ': PSMILe_Get_comp_handle: start'

      call psmile_flushstd
#endif /* VERBOSE */

!----------------------------------------------------------------------
!   Initialization
!----------------------------------------------------------------------

      ierror  = 0
      comp_id = 0

!----------------------------------------------------------------------
!   Search in list for the component name and return its index
!----------------------------------------------------------------------

      do i = 1, Number_of_Comps_allocated
         if (Comps(i)%status == PSMILe_status_free) exit
      end do

      if ( i <= Number_of_Comps_allocated) then

         comp_id = i

      else
!
!   ... Allocate new Components vector, initialise and copy old vector
!
         new_dim = Number_of_Comps_allocated + 8
!
         Allocate (New_Comps (new_dim), STAT = ierror)
         if (ierror > 0) then
            ierrp (1) = ierror
            ierrp (2) = new_dim
            ierror = PRISM_Error_Alloc

            call psmile_error ( ierror, 'New_Comps', &
                                ierrp, 2, __FILE__, __LINE__ )
            return
         endif
!
         New_Comps (1:Number_of_Comps_allocated) = &
             Comps (1:Number_of_Comps_allocated)

         New_Comps(Number_of_Comps_allocated+1:new_dim)%status = &
             PSMILe_status_free
!
!   ... De-allocate Comps vector
!
         Deallocate (Comps, STAT = ierror)
         if (ierror > 0) then
            ierrp (1) = ierror
            ierror = PRISM_Error_Dealloc

            call psmile_error ( ierror, 'Comps', &
                                ierrp, 1, __FILE__, __LINE__ )
            return
         endif
!
!   ... Update Number of Components
!
         Comps => New_Comps
!
         comp_id = Number_of_Comps_allocated + 1
!
         Number_of_Comps_allocated = new_dim

      endif

      Comps(comp_id)%status   = PSMILe_status_defined
      Comps(comp_id)%act_comm = MPI_COMM_NULL

#ifdef VERBOSE
      print *, trim(ch_id), ': PSMILe_Get_comp_handle: eof handle, ierror =', &
               comp_id, ierror

      call psmile_flushstd
#endif /* VERBOSE */
!
      end subroutine PSMILe_Get_comp_handle