psmile_mg_prev_levels_3d_real.F90

Go to the documentation of this file.

!-----------------------------------------------------------------------
! Copyright 2006-2010, NEC Europe Ltd., London, UK.
! All rights reserved. Use is subject to OASIS4 license terms.
!-----------------------------------------------------------------------
!BOP
!
! !ROUTINE: PSMILe_MG_Prev_levels_3d_real
!
! !INTERFACE:

      subroutine psmile_mg_prev_levels_3d_real (grid_id, lev, nlev, &
                           lstijk, xyz, found, newijk)
!
! !USES:
!
      use PRISM_constants
!
      use PSMILe, dummy_interface => PSMILe_mg_prev_levels_3d_real

      Implicit none
!
! !INPUT PARAMETERS:
!
      Integer, Intent (In)            :: grid_id
!
!     Grid Id for which the donor cells should be searched.
!
      Integer, Intent (In)            :: lev
!
!     Level number of the next (fine) grid
!
      Integer, Intent (In)            :: nlev
!
!     Total number of levels
!
      Integer, Intent (In)            :: lstijk (ndim_3d)
!
!     Last indices of cell on coarse level LEV+1.
!     !!! This routine assumes that all parts on the fine grid "LEV"
!     of these cells, were already controlled and point "xyz"
!     was not found.
!
      Real, Intent (In)               :: xyz (ndim_3d)
!
!     Coordinates of the points to be searched
!
! !OUTPUT PARAMETERS:
!
      Integer, Intent (Out)           :: found
!
!     Was the point xyz found ?
!     found = 0: Not found
!     found > 0: Part of the cell where point XYZ was found.
!
      Integer, Intent (Out)           :: newijk (ndim_3d)
!
!     Indices on level LEV if found > 0 is returned.
!
! !DEFINED PARAMETERS:
!
      Logical, Parameter              :: wide = .true.
      Logical, Parameter              :: small = .false.
!
! !LOCAL VARIABLES
!
      Integer                      :: i

!     ... for Grid

      Type (Grid), Pointer            :: grid_info

!     ... for levels

      Integer                      :: levc, levd, levdbg, levu, levubg
      Integer                      :: nlev1
      Integer                      :: nold (nlev), ijk (ndim_3d, nlev)
      Logical                      :: all (nlev)
!
! !DESCRIPTION:
!
! Subroutine "PSMILe_mg_prev_levels_3d_real" searches for the donor cell
! of point "sent".  The point was last found on level LEVC in donor cell (IC).
!
! TODO: Improvements of "psmile_mg_prev_levels_2d_real.F90" to be integrated.
!
!
! !REVISION HISTORY:
!
!   Date      Programmer   Description
! ----------  ----------   -----------
! 03.07.21    H. Ritzdorf  created
!
!EOP
!----------------------------------------------------------------------
!
!  $Id: psmile_mg_prev_levels_3d_real.F90 2325 2010-04-21 15:00:07Z valcke $
!  $Author: valcke $
!
   Character(len=len_cvs_string), save :: mycvs = 
       '$Id: psmile_mg_prev_levels_3d_real.F90 2325 2010-04-21 15:00:07Z valcke $'
!
!----------------------------------------------------------------------
!
!  Initialization
!
#ifdef VERBOSE
      print 9990, trim(ch_id), lev

      call psmile_flushstd
#endif /* VERBOSE */
!
      grid_info => Grids(grid_id)

      levc = lev + 1
      nlev1 = nlev - 1

#ifdef PRISM_ASSERTION
      if (levc >= nlev) then
         call psmile_assert (__FILE__, __LINE__, 'incorrect level')
      endif
#endif
!
      ijk (:, levc) = lstijk (:)
!
         do levd = levc, nlev1
         all  (levd) = .false.
         nold (levd) = 1
         end do
!
!===> ... Compute indices on the coarser levels
!         for coarsening factor 2 !
!
         do levd = levc+1, nlev1
            do i = 1, ndim_3d
            if (grid_info%mg_infos(levd  )%levdim(i) /= &
                grid_info%mg_infos(levd-1)%levdim(i) ) then
               ijk (i, levd) = ijk (i, levd-1) / 2
            else
               ijk (i, levd) = ijk (i, levd-1)
            endif
            end do
         end do
!
!---------------------------------------------------------------------
!     Go down in the level hierarchie
!---------------------------------------------------------------------
!
      levdbg = levc
!
100   continue
!
         do levd = levdbg, nlev1
!
         call psmile_mg_control_cell_3d_real ( &
             grid_info%mg_infos(levd)%real_arrays%chmin(1)%vector, &
             grid_info%mg_infos(levd)%real_arrays%chmin(2)%vector, &
             grid_info%mg_infos(levd)%real_arrays%chmin(3)%vector, &
             grid_info%mg_infos(levd)%real_arrays%chmax(1)%vector, &
             grid_info%mg_infos(levd)%real_arrays%chmax(2)%vector, &
             grid_info%mg_infos(levd)%real_arrays%chmax(3)%vector, &
             grid_info%mg_infos(levd)%real_arrays%midp (1)%vector, &
             grid_info%mg_infos(levd)%real_arrays%midp (2)%vector, &
             grid_info%mg_infos(levd)%real_arrays%midp (3)%vector, &
             grid_info%mg_infos(levd)%levdim, &
             ijk(1, levd), xyz, nold(levd), all(levd), wide, found, newijk)
!
         if (found > 0) go to 1990
!
         end do
!
!===> Not found
!

#ifdef VERBOSE
      print 9980, trim(ch_id), lev

      call psmile_flushstd
#endif /* VERBOSE */

      return
!
!---------------------------------------------------------------------
!     Up again; startpoint is newijk on level "levd"
!---------------------------------------------------------------------
!
1990  nold (levd) = found
      all (levd) = .true.
!
      levdbg = levd
      levubg = levd - 1
!
      nold (levubg) = 0
      all  (levubg) = .true.
!
         do i = 1, ndim_3d
         if (grid_info%mg_infos(levubg)%levdim(i) > &
             grid_info%mg_infos(levubg+1)%levdim(i)) then
            ijk (i, levubg) = min (newijk(i)*2, grid_info%mg_infos(levubg)%levdim(i))
         else
            ijk (i, levubg) = newijk (i)
         endif
         enddo
!
1995  continue
!
         do levu = levubg, lev, -1
         if (levu .ne. levubg) then
            do i = 1, ndim_3d
               if (grid_info%mg_infos(levu)%levdim(i) > &
                   grid_info%mg_infos(levu+1)%levdim(i)) then
                  ijk (i, levu) = min (newijk(i)*2, grid_info%mg_infos(levu)%levdim(i))
               else
                  ijk (i, levu) = newijk (i)
               endif
            enddo
         endif
!
         call psmile_mg_control_cell_3d_real ( &
             grid_info%mg_infos(levu)%real_arrays%chmin(1)%vector, &
             grid_info%mg_infos(levu)%real_arrays%chmin(2)%vector, &
             grid_info%mg_infos(levu)%real_arrays%chmin(3)%vector, &
             grid_info%mg_infos(levu)%real_arrays%chmax(1)%vector, &
             grid_info%mg_infos(levu)%real_arrays%chmax(2)%vector, &
             grid_info%mg_infos(levu)%real_arrays%chmax(3)%vector, &
             grid_info%mg_infos(levu)%real_arrays%midp (1)%vector, &
             grid_info%mg_infos(levu)%real_arrays%midp (2)%vector, &
             grid_info%mg_infos(levu)%real_arrays%midp (3)%vector, &
             grid_info%mg_infos(levu)%levdim,                   &
             ijk(1, levu), xyz, nold(levu), all(levu), small, found, newijk)
!
         if (found == 0) then
            if (levu < levd-1) then
!
!===> ... go back to the previous level; and try again
!
               levubg = levu + 1
               go to 1995
            else
!
!===> ... go down
!
               go to 100
            endif
!
         else if (levu > lev) then
            all (levu) = .true.
            nold (levu) = found
!
            nold (levu-1) = 0
            all (levu-1) = .true.
         endif
         end do ! levu
!
!===> All done
!
#ifdef VERBOSE
      print 9980, trim(ch_id), lev

      call psmile_flushstd
#endif /* VERBOSE */
!
      return
!
!  Formats:
!
9990 format (1x, a, ': psmile_mg_prev_levels_3d_real: level', i3, &
                    ', ibeg, iend', 2i6)
9980 format (1x, a, ': psmile_mg_prev_levels_3d_real: eof, level', i3)

      end subroutine PSMILe_mg_prev_levels_3d_real