psmile_neigh_nearx_irr2_3d_dble.F90

Go to the documentation of this file.

!-----------------------------------------------------------------------
! Copyright 2006-2010, NEC Europe Ltd., London, UK.
! All rights reserved. Use is subject to OASIS4 license terms.
!-----------------------------------------------------------------------
!BOP
!
! !ROUTINE: PSMILe_Neigh_nearx_irr2_3d_dble
!
! !INTERFACE:

      subroutine psmile_neigh_nearx_irr2_3d_dble (grid_id,        &
                      coords1, coords2, coords3,                  &
                      x_coords, y_coords, z_coords, coords_shape, &
                      mask_array, mask_shape, mask_available,     &
                      sin_values, cos_values, grid_valid_shape,   &
                      search_mode, srcloc, nloc, nprev, nsearch,  &
                      neighbors_3d, num_neigh,                    &
                      extra_search, ierror)
!
! !USES:
!
      use PRISM_constants
!
      use PSMILe, dummy_interface => PSMILe_Neigh_nearx_irr2_3d_dble

      Implicit none
!
! !INPUT PARAMETERS:
!
      Integer, Intent (In)            :: grid_id

!     Link to the info on the component in which the donor cells
!     should be searched.

      Integer, Intent (In)            :: nloc
!
!     Total number of locations to be transferred
!
      Integer, Intent (In)            :: nprev
!
!     Number of locations for which neighbours were already searched.
!
      Integer, Intent (In)            :: nsearch
!
!     Number of locations for which neighbours should be searched in this
!     sweep.
!
      Integer, Intent (In)            :: srcloc (ndim_3d, nloc)

!     Indices of the grid cell in which the point was found.
!
      Double Precision, Intent (In)   :: coords1 (nloc)
      Double Precision, Intent (In)   :: coords2 (nloc)
      Double Precision, Intent (In)   :: coords3 (nloc)

!     Coordinates of the target points (which were searched and found)

      Integer, Intent (In)            :: coords_shape (2, ndim_3d)

!     Dimension of coordinates (method) x_coords, ...

      Double Precision, Intent (In)   ::               
         x_coords(coords_shape(1,1):coords_shape(2,1), 
                  coords_shape(1,2):coords_shape(2,2))
      Double Precision, Intent (In)   ::               
         y_coords(coords_shape(1,1):coords_shape(2,1), 
                  coords_shape(1,2):coords_shape(2,2))
      Double Precision, Intent (In)   ::               
         z_coords(coords_shape(1,3):coords_shape(2,3))

!     Coordinates of the method

      Integer, Intent (In)            :: mask_shape (2, ndim_3d)

!     Dimension of (method) mask array

      Logical, Intent (In)            :: 
         mask_array (mask_shape (1,1):mask_shape (2,1), 
                     mask_shape (1,2):mask_shape (2,2), 
                     mask_shape (1,3):mask_shape (2,3))
!     Mask of the method

      Logical, Intent (In)            :: mask_available

!     Is mask specified in array "mask_array" ?
!     mask_available = .false. : Mask is not available
!                      .true.  : Mask is     available

      Integer, Intent (In)            :: grid_valid_shape (2, ndim_3d)

!     Specifies the valid block shape for the "ndim_3d"-dimensional block

      Double Precision, Intent (In)   :: 
         sin_values (grid_valid_shape(1,1):grid_valid_shape(2,1), 
                     grid_valid_shape(1,2):grid_valid_shape(2,2), 2)
!
!     Sin values of Longitudes and Latitudes (x_coords, y_coords)
!
      Double Precision, Intent (In)   :: 
         cos_values (grid_valid_shape(1,1):grid_valid_shape(2,1), 
                     grid_valid_shape(1,2):grid_valid_shape(2,2), 2)
!    
!     Cos values of Longitudes and Latitudes (x_coords, y_coords)
!
      Integer, Intent (In)            :: search_mode
!
!     Specifies the search mode for nearest neigbours with
!        search_mode = 3 : Full 3d-search
!        search_mode = 2 : Search in 2d-hyperplane (1st 2 direction lon, lat)

      Integer, Intent (In)            :: num_neigh
!
!     Last dimension of neighbors array "neighbors_3d" and
!     number of neighbors to be searched.
!
! !INPUT/OUTPUT PARAMETERS:
!
      Type (Extra_search_info)        :: extra_search
!
!     Number of locations where
!       (*) required mask values were not true
!
! !OUTPUT PARAMETERS:
!
      Integer, Intent (Out)           :: neighbors_3d (ndim_3d, nloc, num_neigh)

!     Indices of neighbor locations (interpolation bases)
!
      Integer, Intent (Out)           :: ierror

!     Returns the error code of PSMILE_Neigh_nearx_irr2_3d_dble;
!             ierror = 0 : No error
!             ierror > 0 : Severe error
!
! !DEFINED PARAMETERS:
!
!  lon   = Index of Longitudes in arrays "sin_values" and "cos_values"
!  lat   = Index of Latitudes  in arrays "sin_values" and "cos_values"
!
      Integer, Parameter              :: lon = 1
      Integer, Parameter              :: lat = 2
!
! !LOCAL VARIABLES
!
!     ... For locations controlled
!
      Double Precision, Pointer       :: sin_search (:, :)
      Double Precision, Pointer       :: cos_search (:, :)
      Double Precision, Pointer       :: z_search (:)
!
!     ... (1d) Indices in (entire) data to be extra searched
!
      Integer                         :: i, ibeg, iend
      Integer                         :: j, jbeg, jend
!
      Integer, Pointer                :: indices (:)
!
!     ... 3d Indices in local data to be extra searched
!
      Integer                         :: sd
      Integer                         :: ijk0 (ndim_3d)
      Integer, Pointer                :: ijk (:, :)
      Integer                         :: width (ndim_3d)
!
!     ... for error handling
!
      Integer, Parameter              :: nerrp = 2
      Integer                         :: ierrp (nerrp)
!
!
! !DESCRIPTION:
!
! Subroutine "PSMILe_Neigh_nearx_irr2_3d_dble" searches the next "num_neigh"
! nearest neighbours on the method-grid (x_coords, y_coords, z_coords)
! for the subgrid coords sent by the destination process.
!
! There are 2 different of search modes supported by the routine:
! search_mode = 3: The nearest neighbours are searched are searched
!                  within the 3d region.
! search_mode = 2: The nearest neighbours are searched only in the
!                  2d hyperplane (lon- and lat-direction).
!
! Subroutine "PSMILe_Neigh_nearx_irr2_3d_dble" is designed for source grids of
! of type "PRISM_Irrlonlat_regvrt" and destination grids of type
! "PRISM_Irrlonlatvrt".
!
! !REVISION HISTORY:
!
!   Date      Programmer   Description
! ----------  ----------   -----------
! 03.07.06    H. Ritzdorf  created
!
!EOP
!----------------------------------------------------------------------
!
!  $Id: psmile_neigh_nearx_irr2_3d_dble.F90 3018 2011-03-16 12:56:53Z redler $
!  $Author: redler $
!
   Character(len=len_cvs_string), save :: mycvs = 
       '$Id: psmile_neigh_nearx_irr2_3d_dble.F90 3018 2011-03-16 12:56:53Z redler $'
!                            
!----------------------------------------------------------------------
!
!  Initialization
!
#ifdef VERBOSE
      print 9990, trim(ch_id)

      call psmile_flushstd
#endif /* VERBOSE */
!
      ierror = 0
!
      ibeg = nprev + 1
      iend = nprev + nsearch
!
      indices => extra_search%indices
!
!===> Get range in indices to be controlled
!     Note: indices are locations in the full 3d cube and
!           contains the previous numbers
!           TODO: DAS SOLLTE in lokale Indices aendern
!
      do jbeg = 1, extra_search%n_extra
         if (indices(jbeg) >= ibeg) exit
      end do
!
      if (jbeg > extra_search%n_extra) then
#ifdef VERBOSE
         print 9980, trim(ch_id), ierror
         call psmile_flushstd
#endif /* VERBOSE */
         return
      endif
!
      do jend = jbeg, extra_search%n_extra
         if (indices(jend) > iend) exit
      end do
      jend = jend - 1
!
      if (jbeg > jend) then
#ifdef VERBOSE
         print 9980, trim(ch_id), ierror
         call psmile_flushstd
#endif /* VERBOSE */
         return
      endif
!
      ibeg = indices(jbeg)
      iend = indices(jend)
!
#ifdef PRISM_ASSERTION
!
!===> Internal control
!
      if (search_mode < 2 .or. search_mode > ndim_3d) then
         print *, trim(ch_id), " search_mode ", search_mode
         call psmile_assert (__FILE__, __LINE__, &
                             'search_mode is out of range ')
      endif
!
      if (nloc < nprev+nsearch ) then
         print *, trim(ch_id), " nloc, nprev, nsearch ", nloc, nprev, nsearch
         call psmile_assert (__FILE__, __LINE__, &
                             'nloc < nprev + PRODUCT (nlocs) ')
      endif
!
!===> Are the locations within the correct shape ?
!
!cdir vector
         do j = jbeg, jend
         i = indices(j)
!
         if (srcloc(1,i) < coords_shape(1,1) -1 .or. &
             srcloc(1,i) > coords_shape(2,1)    .or. &
             srcloc(2,i) < coords_shape(1,2) -1 .or. &
             srcloc(2,i) > coords_shape(2,2)    .or. &
             srcloc(3,i) < coords_shape(1,3) -1 .or. &
             srcloc(3,i) > coords_shape(2,3)) exit
         end do
!
      if (j <= jend) then
         print *, "i, j, jbeg, jend", i, j, jbeg, jend
         print *, "srcloc ", srcloc(:, i)
         print *, "shape  ", coords_shape
         call psmile_assert (__FILE__, __LINE__, &
                             'wrong index')
      endif
#endif
!
!-----------------------------------------------------------------------
!     Allocate and set temporary array which is used to transform
!     the coordinates of points to be searched.
!     (*) Longitudes and Latitudes are transformed
!         from degrees into radients.
!     (*) The z-values are currently not transformed
!         ??? Whats about PRISM_Irrlonlat_sigmavrt, ...
!
!     If global search is required, the values are stored in
!     structure "extra_seach" in order to be reused.
!-----------------------------------------------------------------------
!
      if (extra_search%global_search) then

         sin_search => extra_search%sin_search_dble
         cos_search => extra_search%cos_search_dble
           z_search => extra_search%z_search_dble

      else

         Allocate (sin_search(jbeg:jend, lat), &
                   cos_search(jbeg:jend, lat), &
                     z_search(jbeg:jend), STAT = ierror)

         if ( ierror > 0 ) then
            ierrp (1) = ierror
            ierrp (2) = (jend-jbeg+1) * (lat * 2 +  1)

            ierror = PRISM_Error_Alloc
            call psmile_error ( ierror, 'sin_search, ..., z_search', &
                                ierrp, 2, __FILE__, __LINE__ )
            return
         endif

      endif
!
      Allocate (ijk(ndim_3d, jbeg:jend), STAT = ierror)

      if ( ierror > 0 ) then
         ierrp (1) = ierror
         ierrp (2) = (jend-jbeg+1) * ndim_3d

         ierror = PRISM_Error_Alloc
         call psmile_error ( ierror, 'ijk', &
                             ierrp, 2, __FILE__, __LINE__ )
         return
      endif
!
!===> Compute values required to compute distances
!
!cdir vector
         do j = jbeg, jend
         sin_search (j, lon) = coords1 (indices(j)) * dble_deg2rad
         end do
!
!cdir vector
         do j = jbeg, jend
         sin_search (j, lat) = coords2 (indices(j)) * dble_deg2rad
         end do
!
      cos_search (jbeg:jend, :) = cos (sin_search (jbeg:jend, :))
      sin_search (jbeg:jend, :) = sin (sin_search (jbeg:jend, :))
!
!cdir vector
         do j = jbeg, jend
         z_search (j) = coords3 (indices(j))
         end do
!
!-----------------------------------------------------------------------
!     Compute coarse grid indices
!-----------------------------------------------------------------------
!
      ijk0 = Grids(grid_id)%ijk0
!
!===> Get coarse grid index on level nlev-2.
!     By coarsening with a faktor of 4
!
      sd = search_mode
      width (1:sd) = 3
!
      if (search_mode == 2) then
         ijk (ndim_3d, jbeg:jend) = srcloc (ndim_3d, indices(jbeg:jend))
!
         width (ndim_3d) = 0
      endif
!
         do i = 1, sd
         ijk (i, jbeg:jend) = ijk0(i) + &
                              ((srcloc(i, indices(jbeg:jend)) - &
                               ijk0(i)) / 4) * 4
         end do ! i
!
!===> Compute nearest neigbours for all points
!     specified in "indices(jbeg:jend)"
!     TODO: sub-arrays "sin_search(jbeg:jend,:)" vermeiden
!
      call psmile_neigh_nearx_sub_irr_dble (grid_id,                  &
              x_coords, y_coords, z_coords, coords_shape,             &
              mask_array, mask_shape, mask_available,                 &
              sin_values, cos_values, grid_valid_shape, search_mode,  &
              neighbors_3d, num_neigh, nloc, extra_search,            &
              ijk, sin_search(jbeg:jend,:), cos_search(jbeg:jend,:),  &
                     z_search(jbeg:jend), jbeg, jend,                 &
              width, ierror)
!
!===> Deallocate memory
!
      Deallocate (ijk)
!
      if (.not. extra_search%global_search) then
         Deallocate (sin_search, cos_search, z_search)
      endif
!
!===> All done
!
#ifdef VERBOSE
      print 9980, trim(ch_id), ierror

      call psmile_flushstd
#endif /* VERBOSE */
!
!  Formats:
!
9990 format (1x, a, ': psmile_neigh_nearx_irr2_3d_dble')
9980 format (1x, a, ': psmile_neigh_nearx_irr2_3d_dble: eof, ierror =', i3)

      end subroutine PSMILe_Neigh_nearx_irr2_3d_dble