psmile_neigh_nearx_sub_reg_real.F90

Go to the documentation of this file.

!-----------------------------------------------------------------------
! Copyright 2006-2010, NEC Europe Ltd., London, UK.
! All rights reserved. Use is subject to OASIS4 license terms.
!-----------------------------------------------------------------------
!BOP
!
! !ROUTINE: PSMILe_Neigh_nearx_sub_reg_real
!
! !INTERFACE:

      subroutine psmile_neigh_nearx_sub_reg_real (           &
                           grid_id,                          &
                           x_coords, y_coords, z_coords,     &
                           coords_shape,                     &
                           mask_array, mask_shape,  mask_available,    &
                           sin_values_lon, cos_values_lon,   &
                           sin_values_lat, cos_values_lat,   &
                           grid_valid_shape, search_mode,    &
                           neighbors_3d, num_neigh, nloc,    &
                           extra_search, ijk,                &
                           sin_search, cos_search, z_search, &
                           jbeg, jend, width, ierror)
!
! !USES:
!
      use PRISM_constants
!
      use PSMILe, dummy_interface => PSMILe_Neigh_nearx_sub_reg_real

      implicit none

! !DEFINED PARAMETERS:
!
!  NREF_3D = Number of locations in 3d to be controlled
!          = 4 ** ndim_3d
!  NREF_2D = Number of locations in 2d to be controlled
!          = 4 ** ndim_2d
!  NREF_1D = Number of locations in 1d to be controlled
!          = 4 ** ndim_1d
!
!  lon   = Index of Longitudes in arrays "sin_values" and "cos_values"
!  lat   = Index of Latitudes  in arrays "sin_values" and "cos_values"
!  real_earth = Earth radius in meter
!
      Integer, Parameter              :: nref_3d = 4 * 4 * 4
      Integer, Parameter              :: nref_2d = 4 * 4
      Integer, Parameter              :: nref_1d = 4
      Integer, Parameter              :: lon = 1
      Integer, Parameter              :: lat = 2
      Integer, Parameter              :: maxlen = 4
!
      Real, Parameter                 :: real_earth = 6400000.0
!
      Real, Parameter                 :: tol = 1d-6 ! muss argument werden
      Real, Parameter                 :: eps = 1d-6
      Real, Parameter                 :: acosp1 =  1.0
      Real, Parameter                 :: acosm1 = -1.0
!
! !INPUT PARAMETERS:
!
      Integer, Intent (In)            :: grid_id

!     Info on the component in which the donor cells
!     should be searched.

      Integer, Intent (In)            :: nloc
!
!     Total number of locations to be transferred
!
      Integer, Intent (In)            :: coords_shape (2, ndim_3d)

!     Dimension of coordinates (method) x_coords, ...

      Real, Intent (In)               :: x_coords(coords_shape(1,1): 
                                                  coords_shape(2,1))
      Real, Intent (In)               :: y_coords(coords_shape(1,2): 
                                                  coords_shape(2,2))
      Real, Intent (In)               :: z_coords(coords_shape(1,3): 
                                                  coords_shape(2,3))

!     Coordinates of the method

      Integer, Intent (In)            :: mask_shape (2, ndim_3d)

!     Dimension of (method) mask array

      Logical, Intent (In)            :: mask_array (mask_shape (1,1): 
                                                     mask_shape (2,1), 
                                                     mask_shape (1,2): 
                                                     mask_shape (2,2), 
                                                     mask_shape (1,3): 
                                                     mask_shape (2,3))
!     Mask of the method

      Logical, Intent (In)            :: mask_available

!     Is mask specified in array "mask_array" ?
!     mask_available = .false. : Mask is not available
!                      .true.  : Mask is     available

      Integer, Intent (In)            :: grid_valid_shape (2, ndim_3d)

!     Specifies the valid block shape for the "ndim_3d"-dimensional block

      Real, Intent (In)               :: sin_values_lon (grid_valid_shape(1,1): 
                                                         grid_valid_shape(2,1))
      Real, Intent (In)               :: sin_values_lat (grid_valid_shape(1,2): 
                                                         grid_valid_shape(2,2))
!
!     Sin values of Longitudes and Latitudes (x_coords, y_coords)
!
      Real, Intent (In)               :: cos_values_lon (grid_valid_shape(1,1): 
                                                         grid_valid_shape(2,1))
      Real, Intent (In)               :: cos_values_lat (grid_valid_shape(1,2): 
                                                         grid_valid_shape(2,2))
!    
!     Cos values of Longitudes and Latitudes (x_coords, y_coords)
!
      Integer, Intent (In)            :: search_mode
!
!     Specifies the search mode for nearest neigbours with
!        search_mode = 3 : Full 3d-search
!        search_mode = 2 : Search in 2d-hyperplane (1st 2 direction lon, lat)
!        search_mode = 1 : Search in 1d-plane

      Integer, Intent (In)            :: num_neigh
!
!     Last dimension of neighbors array "neighbors_3d" and
!     number of neighbors to be searched.
!
      Integer,          Intent (In)   :: jbeg, jend
!
!     Dimensioning of arrays
!
      Integer,          Intent (In)   :: ijk (ndim_3d, jbeg:jend)
!
!     Coarse grid index on level nlev-2 (for dimensions specified 
!     by search mode). Coarsening factor had to be 4.

      Real, Intent (In)               :: sin_search (jbeg:jend, lat)
!
!     Sin values of the points for which the nearest neighbours
!     should be searched.
!
      Real, Intent (In)               :: cos_search (jbeg:jend, lat)
!
!     Cos values of the points for which the nearest neighbours
!     should be searched.
!
      Real, Intent (In)               :: z_search (jbeg:jend)
!
!     Z values of the points for which the nearest neighbours
!     should be searched.
!
      Integer, Intent (In)            :: width (ndim_3d)
!
      Type (Extra_search_info), Intent(In) :: extra_search
!
!     Number of locations where
!       (*) required mask values were not true
!
! !OUTPUT PARAMETERS:
!
      Integer, Intent (Out)           :: neighbors_3d (ndim_3d, nloc, num_neigh)

!     Indices of neighbor locations (interpolation bases)
!
      Integer, Intent (Out)           :: ierror

!     Returns the error code of PSMILE_Neigh_nearx_sub_reg_real;
!             ierror = 0 : No error
!             ierror > 0 : Severe error
!
! !LOCAL VARIABLES
!
!     ... For locations controlled
!
      Integer                         :: nrefv (1:ndim_3d)
      Integer                         :: dim1 (2)
      Logical                         :: global_search
      Real, Pointer                   :: dist_real (:, :)
!
!     ... (1d) Indices in (entire) data to be extra searched
!
      Integer                         :: i, k
      Integer                         :: j, jpart
      Integer                         :: leni, lenj, lenk, lenij
!
      Integer, Pointer                :: indices (:)
!
!     ... 3d Indices in local data to be extra searched
!
      Integer                         :: ii, jj, kk
      Integer                         :: n, nref, nrefd
!
      Integer                         :: ijkdst (ndim_3d, nref_3d)
      Integer                         :: ijkctl (ndim_3d, nref_3d)
      Integer                         :: irange (2, ndim_3d)
!
!     ... auxiliary arrays
!
      Integer                         :: itemp (ndim_3d)
!
!     ... for mask values
!
      Logical                         :: mask_dist (nref_3d)
!
!     ... for nearest neighbour control
!
      Integer                         :: nmin (1)
      Integer                         :: nfound
!
      Real                            :: real_huge
      Real                            :: distance (nref_3d), dist, fac, val

      Integer                         :: nlev
      Type (Extra_search_nn)          :: nn_srch
      Type (Grid), Pointer            :: grid_info
      Type (Extra_search_real)        :: arrays
      Type (Enddef_mg_real), Pointer :: my_arrays
!
!     ... for error handling
!
      Integer, Parameter              :: nerrp = 2
      Integer                         :: ierrp (nerrp)
!
!
! !DESCRIPTION:
!
! Subroutine "PSMILe_Neigh_nearx_sub_reg_real" searches the next "num_neigh"
! nearest neighbours on the method-grid (x_coords, y_coords, z_coords)
! for the extra indices specified in "extra_search%indices".
!
! There are 3 different of search modes supported by the routine:
! search_mode = 3: The nearest neighbours are searched are searched
!                  within the 3d region.
! search_mode = 2: The nearest neighbours are searched only in the
!                  2d hyperplane (lon- and lat-direction).
! search_mode = 1: The nearest neighbours are searched only in the
!                  1d plane.
!
! Subroutine "PSMILe_Neigh_nearx_sub_reg_real" is designed for grids of
! of type "PRISM_Reglonlatvrt".
!
! !REVISION HISTORY:
!
!   Date      Programmer   Description
! ----------  ----------   -----------
! 11.11.04    H. Ritzdorf  created
!
!EOP
!----------------------------------------------------------------------
!
!  $Id: psmile_neigh_nearx_sub_reg_real.F90 2325 2010-04-21 15:00:07Z valcke $
!  $Author: valcke $
!
   Character(len=len_cvs_string), save :: mycvs = 
       '$Id: psmile_neigh_nearx_sub_reg_real.F90 2325 2010-04-21 15:00:07Z valcke $'
!
!----------------------------------------------------------------------
!
!  Relative control indices 
!      
#ifdef OLD
      Integer, Parameter              :: nrefd = 3 * 3 * 3
!
      data ((ijkctl (i, n), i=1,ndim_3d), n = 1,nref_3d) &
                            /  0, 0, 0,                       &
                               1, 0, 0,   0, 1, 0,   0, 0, 1, &
                              -1, 0, 0,   0,-1, 0,   0, 0,-1, &
                              -1,-1, 0,   1,-1, 0,            &
                              -1, 1, 0,   1, 1, 0,            &
                              -1, 0,-1,   1, 0,-1,            &
                              -1, 0, 1,   1, 0, 1,            &
                               0,-1,-1,   0, 1,-1,            &
                               0,-1, 1,   0, 1, 1,            &
                              -1,-1,-1,   1,-1,-1,            &
                              -1, 1,-1,   1, 1,-1, &
                              -1,-1, 1,   1,-1, 1, &
                              -1, 1, 1,   1, 1, 1/
#endif
! schoener waere eine liste, die weniger sortierung (s.o.) nachher verlangt
! veielleicht sollte man immer annehmen, dass ijk in der "Mitte" liegt
!
      data ((ijkctl (i, n), i=1,ndim_3d), n = 1,nref_3d) &
            /  0, 0, 0,   1, 0, 0,   2, 0, 0,   3, 0, 0, &
               0, 1, 0,   1, 1, 0,   2, 1, 0,   3, 1, 0, &
               0, 2, 0,   1, 2, 0,   2, 2, 0,   3, 2, 0, &
               0, 3, 0,   1, 3, 0,   2, 3, 0,   3, 3, 0, &
               0, 0, 1,   1, 0, 1,   2, 0, 1,   3, 0, 1, &
               0, 1, 1,   1, 1, 1,   2, 1, 1,   3, 1, 1, &
               0, 2, 1,   1, 2, 1,   2, 2, 1,   3, 2, 1, &
               0, 3, 1,   1, 3, 1,   2, 3, 1,   3, 3, 1, &
               0, 0, 2,   1, 0, 2,   2, 0, 2,   3, 0, 2, &
               0, 1, 2,   1, 1, 2,   2, 1, 2,   3, 1, 2, &
               0, 2, 2,   1, 2, 2,   2, 2, 2,   3, 2, 2, &
               0, 3, 2,   1, 3, 2,   2, 3, 2,   3, 3, 2, &
               0, 0, 3,   1, 0, 3,   2, 0, 3,   3, 0, 3, &
               0, 1, 3,   1, 1, 3,   2, 1, 3,   3, 1, 3, &
               0, 2, 3,   1, 2, 3,   2, 2, 3,   3, 2, 3, &
               0, 3, 3,   1, 3, 3,   2, 3, 3,   3, 3, 3/
!
      data nrefv /nref_1d, nref_2d, nref_3d/
!                            
!----------------------------------------------------------------------
!
!  Initialization
!
#ifdef VERBOSE
      print 9990, trim(ch_id)

      call psmile_flushstd
#endif /* VERBOSE */
!
      ierror = 0

      grid_info => Grids(grid_id)
      indices   => extra_search%indices
      global_search = extra_search%global_search
!
      real_huge = huge (distance(1))
!
!===> Allocate vector to store the distances found if required
!
      if (global_search) then
         dist_real => extra_search%dist_real
         dim1 (1) = 1
         dim1 (2) = extra_search%n_extra
      else
         dim1 (1) = jbeg
         dim1 (2) = jend
!
         Allocate (dist_real (jbeg:jend, num_neigh), stat = ierror)

         if (ierror /= 0) then
            ierrp (1) = ierror
            ierrp (2) = num_neigh * (jend-jbeg+1)

            ierror = PRISM_Error_Alloc
            call psmile_error ( ierror, 'dist_real', ierrp, 2, &
                __FILE__, __LINE__ ) 
            return
         endif
      endif
!
#ifdef PRISM_ASERTION
      if (global_search) then
         if (.not. Associated (extra_search%dist_real)) then
            call psmile_assert (__FILE__, &
                __LINE__, 'extra_search%dist_real was not allocated')
         endif
      endif
#endif
!
!===> Get number of reference points
!
      nrefd = nrefv (search_mode)
!
!===> Compute distances for each point in (jbeg:jend)
!
      do jpart = jbeg, jend, 5000

!cdir vector loopcnt=5000
         do j = jpart, min(jend, jpart+5000-1)

         i = indices(j)
!
!===> ... Get standard range to be controlled
!
         irange (1, :) = max (ijk(:, j),          grid_valid_shape (1, :))
         irange (2, :) = min (ijk(:, j)+width(:), grid_valid_shape (2, :))
!
         nref = (irange (2,1) - irange (1,1) + 1) * &
                (irange (2,2) - irange (1,2) + 1) * &
                (irange (2,3) - irange (1,3) + 1)
!
#ifdef PRISM_ASSERTION
!
         if (nref > nrefd) then
            print *, trim(ch_id), " nref, nredfd", nref, nrefd
            call psmile_assert (__FILE__, &
        __LINE__, 'nref > nrefd ')
         endif
#endif
!
!===> ... Set indices to be controlled
!
         if (nref == nrefd) then
               do n = 1, nrefd
               ijkdst (:, n) = ijk (:, j) + ijkctl (:, n)
               end do
               if ( Grids(grid_id)%grid_type == PRISM_Gaussreduced_regvrt ) ijkdst (2, :) = 1
         else
! 
            leni  =  irange (2, 1) - irange (1, 1) + 1
            lenij = (irange (2, 2) - irange (1, 2) + 1) * leni 
!
               do kk = 1, irange (2,3)-irange(1,3) + 1
               n = (kk-1)*lenij
                  do jj = 1, irange (2,2)-irange(1,2) + 1

!cdir vector
                     do ii = 1, leni
                     ijkdst (1, n+ii) = irange(1,1) + ii - 1
                     end do ! ii

                  ijkdst (2, n+1:n+leni) = irange (1,2) + jj - 1
                  n = n + leni
                  end do ! jj

               ijkdst (3, (kk-1)*lenij+1:kk*lenij) = irange (1,3) + kk - 1
               end do ! kk
               if ( Grids(grid_id)%grid_type == PRISM_Gaussreduced_regvrt ) ijkdst (2, :) = 1
         endif
!
!====> ... Get Mask values if necessary
!
         if (mask_available) then
!cdir vector
               do n = 1, nref
               mask_dist (n) = mask_array (ijkdst (1,n), ijkdst (2,n), &
                                           ijkdst (3,n))
               end do
!
            n = count (mask_dist(1:nref))
!
            if (n == 0) then
!              no value available
!
               nref = 0
               go to 10
            endif
!
            if (n < nref) then
               n = 0
                  do ii = 1, nref
                  if (mask_dist (ii)) then
                      n = n + 1
                      if (n /= ii) ijkdst (:, n) = ijkdst (:, ii)
                  endif
                  end do
               nref = n
               if ( Grids(grid_id)%grid_type == PRISM_Gaussreduced_regvrt ) ijkdst (2, :) = 1
            endif
         endif
!
!===> ... Compute distances to points
!
         fac = real_earth + z_search (j)
!
!cdir vector
            do n = 1, nref
            if ( Grids(grid_id)%grid_type == PRISM_Gaussreduced_regvrt ) then
            val   = (  sin_values_lat(ijkdst (1,n)) * sin_search(j, lat)    &
                    +  cos_values_lat(ijkdst (1,n)) * cos_search(j, lat)    &
                    * (cos_values_lon(ijkdst (1,n)) * cos_search(j, lon)    &
                      +sin_values_lon(ijkdst (1,n)) * sin_search(j, lon)) )
            else
            val   = (  sin_values_lat(ijkdst (2,n)) * sin_search(j, lat)    &
                    +  cos_values_lat(ijkdst (2,n)) * cos_search(j, lat)    &
                    * (cos_values_lon(ijkdst (1,n)) * cos_search(j, lon)    &
                      +sin_values_lon(ijkdst (1,n)) * sin_search(j, lon)) )
            endif
#ifdef PRISM_ASSERTION
            if (val < acosm1 - eps .or. val > acosp1 + eps) then
               print *, i, j, val
               call psmile_assert (__FILE__, __LINE__, &
                                   'invalid value for acos')
            endif
#endif
            val = min (acosp1, val)
            val = max (acosm1, val)

            dist = fac * acos (val)

            distance (n) = dist*dist +                                 &
                           ( z_search (j)-z_coords(ijkdst (3,n)))**2
#ifdef DEBUG2
            if (i == 2) then
               print *, 'n, distance, dist, diff', n, distance (n), dist, &
                        z_search (j)-z_coords(ijkdst (3,n))
            endif
#endif
            end do ! n
!
         nmin = minloc (distance(1:nref))
#ifdef MINLOCFIX
         if (nmin(1).eq.0) nmin=1
#endif /* MINLOCFIX */
!
#ifdef DEBUG2
         if (i == 2) then
            print *, 'psmile_neigh_nearx_sub_reg_real: ictl =', i, j, k
            print *, 'ijkdst and distance:'
               do n = 1, nref
               print *, ijkdst (:, n), distance (n)
               end do
         endif
#endif
!
!===> ... Special case: Minimal distance == 0
!         Move other neighbours to "outside" of region.
!
         if (distance(nmin(1)) <= tol) then
            neighbors_3d (:, i, 1) = ijkdst (:, nmin(1))
!
               do n = 2, num_neigh
               neighbors_3d (:, i, n) = grid_valid_shape (1, :) - 1
               end do
!
            dist_real (j, 1:num_neigh) = 0.0
!
            cycle
         endif
!
!===> ... Sort distances (silly sort)
!         Da muss noch etwas besseres her !
!
10       continue
!
         nfound = min (num_neigh, nref)
         if (nfound < num_neigh) then
            distance(nfound+1:num_neigh) = real_huge

               do n = nfound+1, num_neigh
               ijkdst (:, n) = grid_valid_shape (1, :) - 1
               end do
         endif
!
            do n = 1, nfound
!
            nmin = minloc (distance(n:nref))
#ifdef MINLOCFIX
            if (nmin(1).eq.0) nmin=1
#endif /* MINLOCFIX */
!
            if (nmin(1) /= 1) then
               jj = n + nmin (1) - 1
!
               itemp  (:)    = ijkdst (:, n)
               ijkdst (:, n) = ijkdst (:, jj)
               ijkdst (:, jj) = itemp  (:)
!
               dist = distance (n)
               distance (n) = distance (jj)
               distance (jj) = dist
            endif
            end do ! n
!
#ifdef PRISM_ASSERTION
            do n = 1, nfound-1
            if (distance(n) > distance (n+1)) exit
            end do
!
         if (n <= nfound-1) then
            print *, 'n =' , n
            print *, 'distance (n)  ', distance (n)
            print *, 'distance (n+1)', distance (n+1)
            print *, 'distance', distance (1:nfound)
            call psmile_assert (__FILE__, __LINE__, &
                                'incorrect sort')
         endif
#endif
!
!===> ... End of local search;
!         fill neighbors_3d and
!         store distances for global search if necessary
!
! Brauche ich die sqrt ?
!
         dist_real (j, 1:nfound) = sqrt (distance (1:nfound))
         if (nfound < num_neigh) then
            dist_real (j, nfound+1:num_neigh) = real_huge

! das sollte man nicht machen (fuer nlev > 2)
! um mg suche einen startpunkt zu geben !
!
               do n = nfound+1, num_neigh
               ijkdst (:, n) = grid_valid_shape (1, :) - 1
               end do
         endif
!
            do n = 1, num_neigh
            neighbors_3d (:, i, n) = ijkdst (:, n)
            end do
!
         end do ! j
      end do ! jpart
!
!=======================================================================
!     Use simple search
!=======================================================================
!
      if ( Grids(grid_id)%grid_type == PRISM_Gaussreduced_regvrt ) then

         call psmile_srch_nneigh_gauss2_real (grid_id, nn_srch, arrays, &
                             search_mode, nref_3d,                      &
                             sin_values_lon, cos_values_lon,            &
                             sin_values_lat, cos_values_lat,            &
                             grid_valid_shape,                          &
                             z_coords, coords_shape,                    &
                             neighbors_3d, nloc, num_neigh,             &
                             sin_search, cos_search, z_search,          &
                             dist_real, dim1, extra_search, jbeg, jend, &
                             mask_array, mask_shape, mask_available,    &
                             tol, ierror)
         if (ierror > 0) return

      else
!
!=======================================================================
!     Use multigrid info for search in other regions
!=======================================================================
!
         if ( grid_info%nlev > 2 ) then
!
!===> Allocate memory and calculate distances on the coarsest level
!     to begin the search for all points.
!
            nlev = max(grid_info%nlev-3,2)
            nn_srch%leni =  grid_info%mg_infos(nlev)%levdim(1) + 1
            nn_srch%lenj =  grid_info%mg_infos(nlev)%levdim(2) + 1
            nn_srch%lenk =  grid_info%mg_infos(nlev)%levdim(3) + 1

            leni = nn_srch%leni
            lenj = nn_srch%lenj
            lenk = nn_srch%lenk

            ii = 0

            allocate(arrays%radius(leni*lenj*lenk), STAT=jj); ii = ii + jj

            allocate(arrays%sin_ccorner_lon(1)%vector(leni), &
                 arrays%cos_ccorner_lon(1)%vector(leni), &
                 arrays%sin_ccorner_lat(1)%vector(lenj), &
                 arrays%cos_ccorner_lat(1)%vector(lenj), STAT=jj); ii = ii + jj

            allocate(arrays%sin_cmidp_lon%vector(leni), &
                 arrays%cos_cmidp_lon%vector(leni), &
                 arrays%sin_cmidp_lat%vector(lenj), &
                 arrays%cos_cmidp_lat%vector(lenj), STAT=jj); ii = ii + jj

            Allocate(arrays%sin_fmidp_lon%vector(maxlen), &
                 arrays%cos_fmidp_lon%vector(maxlen), &
                 arrays%sin_fmidp_lat%vector(maxlen), &
                 arrays%cos_fmidp_lat%vector(maxlen), STAT=jj); ii = ii + jj

            if ( ii /= 0 ) then
               ierrp (1) = ierror
               ierrp (2) = ii

               ierror = PRISM_Error_Alloc
               call psmile_error ( ierror, 'arrays%...%vector', ierrp, 2, &
                    __FILE__, __LINE__ )
               return

            endif

            my_arrays => grid_info%mg_infos(nlev)%real_arrays

            arrays%sin_ccorner_lon(1)%vector(1:leni) = sin(my_arrays%chmin(1)%vector(1:leni)*real_deg2rad)
            arrays%cos_ccorner_lon(1)%vector(1:leni) = cos(my_arrays%chmin(1)%vector(1:leni)*real_deg2rad)
            arrays%sin_ccorner_lat(1)%vector(1:lenj) = sin(my_arrays%chmin(2)%vector(1:lenj)*real_deg2rad)
            arrays%cos_ccorner_lat(1)%vector(1:lenj) = cos(my_arrays%chmin(2)%vector(1:lenj)*real_deg2rad)

            arrays%sin_cmidp_lon%vector(1:leni) = sin(my_arrays%midp(1)%vector(1:leni)*real_deg2rad)
            arrays%cos_cmidp_lon%vector(1:leni) = cos(my_arrays%midp(1)%vector(1:leni)*real_deg2rad)
            arrays%sin_cmidp_lat%vector(1:lenj) = sin(my_arrays%midp(2)%vector(1:lenj)*real_deg2rad)
            arrays%cos_cmidp_lat%vector(1:lenj) = cos(my_arrays%midp(2)%vector(1:lenj)*real_deg2rad)

            n = 0

            do k = 1, lenk
               fac = real_earth + my_arrays%midp(3)%vector(k)
               do j = 1, lenj
                  do i = 1, leni
                     n = n+1

                     val = ( arrays%sin_ccorner_lat(1)%vector(j) * arrays%sin_cmidp_lat%vector(j)    &
                          +  arrays%cos_ccorner_lat(1)%vector(j) * arrays%cos_cmidp_lat%vector(j)    &
                          * (arrays%cos_ccorner_lon(1)%vector(i) * arrays%cos_cmidp_lon%vector(i)    &
                          +  arrays%sin_ccorner_lon(1)%vector(i) * arrays%sin_cmidp_lon%vector(i)) )

                     val = min (acosp1, val)
                     val = max (acosm1, val)

                     dist = fac * acos (val)

                     if ( search_mode == 3 ) then
                        arrays%radius(n) = sqrt(dist*dist+(my_arrays%midp(3)%vector(k)- &
                             my_arrays%chmin(3)%vector(k))**2)
                     else if ( search_mode == 2 ) then
                        arrays%radius(n) = abs(dist)
                     endif

                  enddo
               enddo
            enddo
!
!===> ... Use multigrid info for search in orther regions
!
            call psmile_mg_srch_nneigh_reg_real (grid_id, nn_srch,      &
                      arrays, search_mode, nref_3d, grid_valid_shape,   &
                      neighbors_3d, nloc, num_neigh,                    &
                      sin_search, cos_search, z_search,                 &
                      dist_real, dim1, indices, jbeg, jend,             &
                      mask_array, mask_shape, mask_available,           &
                 tol, ierror)
            if (ierror > 0) return
!
!===> ... Deallocate memory
!
            deallocate(arrays%sin_ccorner_lon(1)%vector, &
                 arrays%cos_ccorner_lon(1)%vector, &
                 arrays%sin_ccorner_lat(1)%vector, &
                 arrays%cos_ccorner_lat(1)%vector)

            deallocate(arrays%sin_cmidp_lon%vector, &
                 arrays%cos_cmidp_lon%vector, &
                 arrays%sin_cmidp_lat%vector, &
                 arrays%cos_cmidp_lat%vector)

            deallocate(arrays%sin_fmidp_lon%vector, &
                 arrays%cos_fmidp_lon%vector, &
                 arrays%sin_fmidp_lat%vector, &
                 arrays%cos_fmidp_lat%vector)

            Deallocate(arrays%radius)
         endif
!
         if (.not. global_search) then
            Deallocate (dist_real)
         endif

      endif
!
!===> All done
!
#ifdef VERBOSE
      print 9980, trim(ch_id), ierror

      call psmile_flushstd
#endif /* VERBOSE */
!
!  Formats:
!
9990 format (1x, a, ': psmile_neigh_nearx_sub_reg_real')
9980 format (1x, a, ': psmile_neigh_nearx_sub_reg_real: eof, ierror =', i3)

      end subroutine PSMILe_Neigh_nearx_sub_reg_real