psmile_recv_req_mask.F90

Go to the documentation of this file.

!-----------------------------------------------------------------------
! Copyright 2006-2010, NEC Europe Ltd., London, UK.
! All rights reserved. Use is subject to OASIS4 license terms.
!-----------------------------------------------------------------------
!BOP
!
! !ROUTINE: PSMILe_Recv_req_mask
!
! !INTERFACE:

      subroutine psmile_recv_req_mask (sender, tag,      &
                                       search, recv_req, &
                                       receive_mask, new_search, ierror)
!
! !USES:
!
      use PRISM_constants
!
      use PSMILe, dummy_interface => PSMILe_Recv_req_mask

      implicit none
!
! !INPUT PARAMETERS:
!
      Integer, Intent (In)                :: sender

!     Specifies the sender of the subgrid.

      Integer, Intent (In)                :: tag

!     Specifies the message tag used

      Logical, Intent (In)                :: receive_mask

!     Should mask array be received ?
!
      Logical, Intent (In)                :: new_search

!     Option:
!     new_search = .true.  : New search; fill search structure
!     new_search = .fasle. : Get only data for a new field
!
! !INPUT/OUTPUT PARAMETERS:
!
      Type (Enddef_search), Intent (InOut) :: search

!     Data on the points to be searched
!
! !OUTPUT PARAMETERS:
!
      integer, Intent (Out)               :: recv_req (ndim_3d+1, search%npart)

!     Receive requests of non-blocking receives
!     The receive requests are stored in recv_req (ndim_3d+1, :).

      integer, Intent (Out)               :: ierror

!     Returns the error code of PSMILe_Recv_req_mask;
!             ierror = 0 : No error
!             ierror > 0 : Severe error
!
! !LOCAL VARIABLES
!
!     ... for the intersections
!
      integer                      :: ipart
      integer                      :: len_mask
!
      logical, save                :: dummy_mask
!
!     ... for error parameters
!
      integer, parameter           :: nerrp = 3
      integer                      :: ierrp (nerrp)
!
! !DESCRIPTION:
!
! Subroutine "PSMILe_Recv_req_mask" receives the mask requested
! from the sending process. The mask is sent after the corresponding
! request was received by routine "PSMILe_Get_intersect".
!
! One receive is submitted at least in order to ensure progress
! in psmile_get_intersect.
!
! !REVISION HISTORY:
!
!   Date      Programmer   Description
! ----------  ----------   -----------
! 03.07.10    H. Ritzdorf  created
!
!EOP
!----------------------------------------------------------------------
!
! $Id: psmile_recv_req_mask.F90 2745 2010-11-18 13:44:51Z hanke $
! $Author: hanke $
!
   Character(len=len_cvs_string), save :: mycvs = 
       '$Id: psmile_recv_req_mask.F90 2745 2010-11-18 13:44:51Z hanke $'
!
!----------------------------------------------------------------------
!
!  Initialization
!
#ifdef VERBOSE
      print 9990, trim(ch_id), sender, search%npart, receive_mask

      call psmile_flushstd
#endif /* VERBOSE */
!
      ierror = 0
!
      recv_req (:, :) = MPI_REQUEST_NULL
!
      if (receive_mask) then
!
! ====================================================================
!     Get dimensions of arrays to be allocated and
!     allocate the arrays.
! ====================================================================

         do ipart = 1, search%npart
!        search_dims(:) = search%range (2,:, ipart) - search%range (1,:, ipart) + 1
!
         len_mask = (search%range(2,1, ipart) - search%range(1,1, ipart) + 1) * &
                    (search%range(2,2, ipart) - search%range(1,2, ipart) + 1) * &
                    (search%range(2,3, ipart) - search%range(1,3, ipart) + 1)
!
!===> ... Post receive for the mask if required
!
         if (new_search .or. .not. Associated (search%search_mask(ipart)%vector)) &
            then

            Allocate (search%search_mask(ipart)%vector(len_mask), STAT = ierror)
            if ( ierror > 0 ) then
               ierrp (1) = ierror
               ierrp (2) = len_mask
               ierror = PRISM_Error_Alloc
               call psmile_error ( ierror, 'search%search_mask(ipart)%vector', &
                                   ierrp, 2, __FILE__, __LINE__ )
               return
            endif
         endif

         call MPI_Irecv (search%search_mask(ipart)%vector, len_mask, &
                         MPI_LOGICAL, &
                         sender, tag, comm_psmile, recv_req (ndim_3d+1, ipart), ierror)
         if (ierror /= MPI_SUCCESS) then
            ierrp (1) = ierror
            ierrp (2) = sender
            ierrp (3) = tag
            ierror = PRISM_Error_Recv

            call psmile_error (ierror, 'MPI_Irecv of mask', &
                               ierrp, 3, __FILE__, __LINE__ )
            return
         endif
         end do ! ipart

      else

!
!        ... Receive is not necessary; free previously allocated masks
!

         if ( Associated(search%search_mask) .and. .not. new_search) then
               do ipart = 1, search%npart
               if (Associated (search%search_mask(ipart)%vector)) then
                  Deallocate  (search%search_mask(ipart)%vector)
               endif

               Nullify (search%search_mask(ipart)%vector)
               end do
         endif

!
!        ... Setup dummy receive in order to get progress in psmile_get_intersect
!
         call MPI_Irecv (dummy_mask, 0, MPI_LOGICAL, &
                         sender, tag, comm_psmile, recv_req (ndim_3d+1, 1), &
                         ierror)
         if (ierror /= MPI_SUCCESS) then
            ierrp (1) = ierror
            ierrp (2) = sender
            ierrp (3) = tag
            ierror = PRISM_Error_Recv

            call psmile_error (ierror, 'MPI_Irecv of mask', &
                               ierrp, 3, __FILE__, __LINE__ )
            return
         endif

      endif
!
!===> All done
!
#ifdef VERBOSE
      print 9980, trim(ch_id), ierror

      call psmile_flushstd
#endif /* VERBOSE */
!
!  Formats:
!
9990 format (1x, a, ': psmile_recv_req_mask: ', &
                    'sender =', i4, ', npart =', i3, ', receive_mask', l2)
9980 format (1x, a, ': psmile_recv_req_mask: eof ierror =', i4)

      end subroutine PSMILe_Recv_req_mask