psmile_store_source_locs_1d.F90

Go to the documentation of this file.

!-----------------------------------------------------------------------
! Copyright 2006-2010, NEC Europe Ltd., London, UK.
! All rights reserved. Use is subject to OASIS4 license terms.
!-----------------------------------------------------------------------
!BOP
      subroutine psmile_store_source_locs_1d (found,  loc,  ibeg,  len,  &
                                              send_info, nloc, opt,      &
                                              ialloc, ipart, nprev, nadd, ierror)
!
! !USES:
!
      use PRISM_constants
!
      use PSMILe, dummy_interface => PSMILe_store_source_locs_1d

      implicit none
!
! !INPUT PARAMETERS:
!
      Integer, Intent (In)            :: ibeg
!
!     Start of search
!
      Integer, Intent (In)            :: len
!
!     Dimension of vectors found and loc
!
      Integer, Intent (In)            :: found  (len)

!     Finest level number on which a grid cell was found for point i,j.
!     Level number = nlev+1: Never found (input value)
!
      Integer, Intent (In)            :: loc  (len)

!     Locations found for coordinates to be searched

      Integer, Intent (In)            :: nloc
!
!     Number of locations to be stored

      Integer, Intent (In)            :: opt
!
!     Option:
!     =  1 : Store values which have to be sent to the coupler;
!            i.e. store locations with found (i,j,k) =  1
!     = -1 : Store values which have to be sent to the application process;
!            i.e. store locations with found (i,j,k) = -1
!     =  0 : Store values with abs(found (i,j,k)) = 1.

      Integer, Intent (In)            :: ialloc
!
!     Index of source locations to be created in "send_info".

      Integer, Intent (In)            :: ipart
!
!     Number of the partition

      Integer, Intent (In)            :: nprev
!
!     Number of locations already stored in send_info%srclocs(ialloc, ipart)%vector
!
! !OUTPUT PARAMETERS:
!
      Type(Send_information), Intent(InOut) :: send_info
!
!     Send information to be generated
!
      Integer, Intent (Out)           :: nadd
!
!     Number of locations added in send_info%srclocs(ialloc, ipart)%vector
!
      integer, Intent (Out)           :: ierror

!     Returns the error code of PSMILe_Store_source_locs_1d;
!             ierror = 0 : No error
!             ierror > 0 : Severe error
!
! !LOCAL VARIABLES
!
      Integer                         :: i, n
!
      Integer, Pointer                :: srcloc (:)
!
!     ... for error handling
!
      Integer, Parameter              :: nerrp = 2
      Integer                         :: ierrp (nerrp)
!
! !DESCRIPTION:
!
! Subroutine "PSMILe_store_source_locs_1d" stores the data on the
! source locations found for the method (grid) and the
! subgrid coords sent by sending (destination) process.
!
! Subroutine "PSMILe_Store_dest_locs_1d" is designed for (1d regular sub-)
! grids of of type "PRISM_Irrlonlat_regvrt".
!
! !REVISION HISTORY:
!
!   Date      Programmer   Description
! ----------  ----------   -----------
! 03.07.03    H. Ritzdorf  created
!
!EOP
!----------------------------------------------------------------------
!
!  $Id: psmile_store_source_locs_1d.F90 2325 2010-04-21 15:00:07Z valcke $
!  $Author: valcke $
!
   Character(len=len_cvs_string), save :: mycvs = 
       '$Id: psmile_store_source_locs_1d.F90 2325 2010-04-21 15:00:07Z valcke $'
!
!----------------------------------------------------------------------
!
!  Initialization
!
#ifdef VERBOSE
      print 9990, trim(ch_id), opt, ibeg, len

      call psmile_flushstd
#endif /* VERBOSE */
!
      ierror = 0
!
      if (nprev == 0 .and. &
          .not. Associated (send_info%srclocs(ialloc, ipart)%vector) ) then

         Allocate (send_info%srclocs(ialloc, ipart)%vector(nloc), STAT = ierror)
         if ( ierror > 0 ) then
            ierrp (1) = ierror
            ierrp (2) = nloc
            call psmile_error ( PRISM_Error_Alloc, 'send_info%srclocs()%vector', &
                                ierrp, 2, __FILE__, __LINE__ )
            return
         endif

      endif
!
! ... Store locations in a simple list
!     ??? Schoener waere eine clusterung in Regions
!     ??? Dann muessen aber die Destionations mit den geclusterten
!         Daten erzeugt werden, um Problem in der Reihenfolge zu verhindern.
!
      srcloc => send_info%srclocs(ialloc, ipart)%vector
!
      n = nprev

      if (opt == 0) then
!cdir vector
          do i = ibeg, len
          if (abs(found (i)) == 1) then
             srcloc (n+1) = loc (i)
             n = n + 1
          endif
          end do
!
      else
!
!cdir vector
          do i = ibeg, len
          if (found (i) == opt) then
             srcloc (n+1) = loc (i)
             n = n + 1
          endif
          end do
      endif

#ifdef PRISM_ASSERTION
      if (nloc < n) then
         print *, "nloc, n", nloc, n
         call psmile_assert ( __FILE__, __LINE__, "nloc < n")
      endif
#endif
!
!===> All done
!
      nadd = n - nprev
!
      send_info%npoints(ialloc, ipart) = send_info%npoints(ialloc, ipart) + nadd
!     send_info%nars   (ialloc, ipart) = send_info%nars   (ialloc, ipart) +

#ifdef DEBUGX
      n = nprev
      if (opt == 0) then
         do i = ibeg, len
         if (abs(found (i)) == 1) then
            n = n + 1
            print *, i, loc(i), n, srcloc(n)
         endif
         end do
      else
         do i = ibeg, len
         if (found (i) == opt) then
            n = n + 1
            print *, i, loc(i), n, srcloc(n)
         endif
         end do
      endif
#endif
!
#ifdef VERBOSE
      print 9980, trim(ch_id), ierror

      call psmile_flushstd
#endif /* VERBOSE */
!
!  Formats:
!
#ifdef VERBOSE

9990 format (1x, a, ': psmile_store_source_locs_1d: opt ', i2, &
             '; ibeg, len ', 2i6)
9980 format (1x, a, ': psmile_store_source_locs_1d: eof ierror =', i3)

#endif /* VERBOSE */

      end subroutine PSMILe_store_source_locs_1d