psmile_store_source_locs_2d.F90

Go to the documentation of this file.

!-----------------------------------------------------------------------
! Copyright 2006-2010, NEC Europe Ltd., London, UK.
! All rights reserved. Use is subject to OASIS4 license terms.
!-----------------------------------------------------------------------
!BOP
      subroutine psmile_store_source_locs_2d (found,  loc,  ibeg,  len,  &
                      send_info, nloc, opt, ialloc, ipart,               &
                      nprev, nadd, ierror)
!
! !USES:
!
      use PRISM_constants
!
      use PSMILe, dummy_interface => PSMILe_store_source_locs_2d

      Implicit none
!
! !INPUT PARAMETERS:
!
      Integer, Intent (In)            :: ibeg
!
!     Start of search
!
      Integer, Intent (In)            :: len
!
!     Dimension of vectors found and loc
!
      Integer, Intent (In)            :: found (len)

!     Finest level number on which a grid cell was found for point "i,j".
!     Level number = nlev+1: Never found (input value)
!
      Integer, Intent (In)            :: loc  (ndim_2d, len)

!     Locations found for coordinates to be searched

      Integer, Intent (In)            :: nloc
!
!     Number of locations to be stored

      Integer, Intent (In)            :: opt
!
!     Option:
!     = -1 : Store values which have to be sent to the coupler;
!            i.e. store locations with found (i,j,k) = -1
!     =  1 : Store values which have to be sent to the application process;
!            i.e. store locations with found (i,j,k) =  1
!     =  0 : Store values with abs(found (i,j,k)) = 1.

      Integer, Intent (In)            :: ialloc
!
!     Index of source locations to be created in "send_info".

      Integer, Intent (In)            :: ipart
!
!     Number of the partition

      Integer, Intent (In)            :: nprev
!
!     Number of locations already stored in
!     send_info%srclocs(ialloc, ipart)%vector
!
! !INPUT/OUTPUT PARAMETERS:
!
      Type(Send_information), Intent(InOut) :: send_info
!
!     Send information to be generated
!
! !OUTPUT PARAMETERS:
!
      Integer, Intent (Out)           :: nadd
!
!     Number of locations added in send_info%srclocs(ialloc, ipart)%vector
!
      Integer, Intent (Out)           :: ierror

!     Returns the error code of PSMILe_Store_source_locs_2d;
!             ierror = 0 : No error
!             ierror > 0 : Severe error
!
! !LOCAL VARIABLES
!
      Integer                         :: i, n
!
      Integer, Pointer                :: srcloc (:)
!
!     ... for error handling
!
      Integer, Parameter              :: nerrp = 2
      Integer                         :: ierrp (nerrp)
!
! !DESCRIPTION:
!
! Subroutine "PSMILe_store_source_locs_2d" stores the data on the
! source locations found for the method (grid) and the
! subgrid coords sent by sending (destination) process.
!
! Subroutine "PSMILe_Store_source_locs_2d" is designed for (2d irregular sub-)
! grids of of type "PRISM_Irrlonlat_regvrt".
!
! !REVISION HISTORY:
!
!   Date      Programmer   Description
! ----------  ----------   -----------
! 03.07.03    H. Ritzdorf  created
!
!EOP
!----------------------------------------------------------------------
!
!  $Id: psmile_store_source_locs_2d.F90 2933 2011-01-31 16:42:27Z hanke $
!  $Author: hanke $
!
   Character(len=len_cvs_string), save :: mycvs = 
       '$Id: psmile_store_source_locs_2d.F90 2933 2011-01-31 16:42:27Z hanke $'
!
!----------------------------------------------------------------------
!
!  Initialization
!
#ifdef VERBOSE
      print 9990, trim(ch_id), opt, ibeg, len

      call psmile_flushstd
#endif /* VERBOSE */
!
      ierror = 0
!
      if (nprev == 0 .and. &
          .not. Associated (send_info%srclocs(ialloc, ipart)%vector) ) then

!        Allocate (send_info%srclocs(ialloc, ipart)%vector(1:ndim_2d, 1:nloc), &
!                  STAT = ierror)
         Allocate (send_info%srclocs(ialloc, ipart)%vector(ndim_2d*nloc), &
                   STAT = ierror)
         if ( ierror > 0 ) then
            ierrp (1) = ierror
            ierrp (2) = nloc * ndim_2d

            ierror = PRISM_Error_Alloc
            call psmile_error ( ierror, 'send_info%srclocs()%vector', &
                                ierrp, 2, __FILE__, __LINE__ )
            return
         endif
      endif
!
! ... Store locations in a simple list
!     ??? Schoener waere eine clusterung in Regions
!     ??? Dann muessen aber die Destionations mit den geclusterten
!         Daten erzeugt werden, um Problem in der Reihenfolge zu verhindern.
!
      srcloc => send_info%srclocs(ialloc, ipart)%vector
!
      n = nprev * ndim_2d
      if (opt == 0) then
!cdir vector
         do i = ibeg, len
            if (abs(found (i)) == 1) then
               srcloc (n+1) = loc (1, i)
               srcloc (n+2) = loc (2, i)

               n = n + ndim_2d
            endif
         end do
!
      else
!
!cdir vector
         do i = ibeg, len
            if (found (i) == opt) then
               srcloc (n+1) = loc (1, i)
               srcloc (n+2) = loc (2, i)

               n = n + ndim_2d
            endif
         end do
      endif

#ifdef PRISM_ASSERTION
      if (nloc*ndim_2d < n) then
         print *, "nloc, n", nloc, n/ndim_2d
         call psmile_assert ( __FILE__, __LINE__, "nloc < n")
      endif
#endif
!
!===> All done
!
      nadd = n/ndim_2d - nprev
!
      send_info%npoints(ialloc, ipart) = send_info%npoints(ialloc, ipart) + nadd
!     send_info%nars   (ialloc, ipart) = send_info%nars   (ialloc, ipart) +
!
#ifdef VERBOSE
      print 9980, trim(ch_id), ierror

      call psmile_flushstd
#endif /* VERBOSE */
!
!  Formats:
!
#ifdef VERBOSE

9990 format (1x, a, ': psmile_store_source_locs_2d: opt ', i2, &
             '; ibeg, len ', 2i6)
9980 format (1x, a, ': psmile_store_source_locs_2d: eof ierror =', i3)

#endif /* VERBOSE */

      end subroutine PSMILe_store_source_locs_2d