psmile_store_source_virt_3d.F90

Go to the documentation of this file.

!-----------------------------------------------------------------------
! Copyright 2006-2010, NEC Europe Ltd., London, UK.
! All rights reserved. Use is subject to OASIS4 license terms.
!-----------------------------------------------------------------------
!BOP
      subroutine psmile_store_source_virt_3d (             &
                      found, virtual_cell, ibeg, len,      &
                      send_info, nloc, opt, ialloc, ipart, &
                      nprev, ierror)
!
! !USES:
!
      use PRISM_constants
!
      use PSMILe, dummy_interface => PSMILe_store_source_virt_3d

      Implicit none
!
! !INPUT PARAMETERS:
!
      Integer, Intent (In)            :: ibeg
!
!     Start of search
!
      Integer, Intent (In)            :: len
!
!     Dimension of vectors found and loc
!
      Integer, Intent (In)            :: found (len)

!     Finest level number on which a grid cell was found for point
!     "i,j,k" or "i,j" (depending on dimension of found).
!     Level number = nlev+1: Never found (input value)
!
      Integer, Intent (In)            :: virtual_cell (len)

!     Locations found for coordinates to be searched

      Integer, Intent (In)            :: nloc
!
!     Number of locations to be stored

      Integer, Intent (In)            :: opt
!
!     Option:
!     = -1 : Store values which have to be sent to the coupler;
!            i.e. store locations with found (i,j,k) = -1
!     =  1 : Store values which have to be sent to the application process;
!            i.e. store locations with found (i,j,k) =  1
!     =  0 : Store values with abs(found (i,j,k)) = 1.

      Integer, Intent (In)            :: ialloc
!
!     Index of source locations to be created in "send_info".

      Integer, Intent (In)            :: ipart
!
!     Number of the partition

      Integer, Intent (In)            :: nprev
!
!     Number of locations already stored in
!     send_info%virtual(ialloc, ipart)%vector
!
! !INPUT/OUTPUT PARAMETERS:
!
      Type(Send_information), Intent(InOut) :: send_info
!
!     Send information to be generated
!
! !OUTPUT PARAMETERS:
!
      Integer, Intent (Out)           :: ierror

!     Returns the error code of PSMILe_Store_source_virt_3d;
!             ierror = 0 : No error
!             ierror > 0 : Severe error
!
! !LOCAL VARIABLES
!
      Integer                         :: i, n
!
      Integer, Pointer                :: virtual (:)
!
!     ... for error handling
!
      Integer, Parameter              :: nerrp = 2
      Integer                         :: ierrp (nerrp)
!
! !DESCRIPTION:
!
! Subroutine "PSMILe_store_source_virt_3d" stores the data on the
! source locations found for the method (grid) and the
! subgrid coords sent by sending (destination) process.
!
! Note: "PSMILe_store_source_virt_3d" is used to store data for
! fully 3-dimensional target grids as well as data for 2d target grids.
! This is the reason why "ialloc" and "ipart" is transferred also
! for fully 3-dimensional grids.
!
!
! !REVISION HISTORY:
!
!   Date      Programmer   Description
! ----------  ----------   -----------
! 13.07.07    H. Ritzdorf  created
!
!EOP
!----------------------------------------------------------------------
!
!  $Id: psmile_store_source_virt_3d.F90,v 1.1.2.1 2007/09/05 10:57:00 ritzdorf Exp $
!  $Author: ritzdorf $
!
   Character(len=len_cvs_string), save :: mycvs = 
       '$Id: psmile_store_source_virt_3d.F90,v 1.1.2.1 2007/09/05 10:57:00 ritzdorf Exp $'
!
!----------------------------------------------------------------------
!
!  Initialization
!
#ifdef VERBOSE
      print 9990, trim(ch_id), opt, nloc, ibeg, len, nprev

      call psmile_flushstd
#endif /* VERBOSE */
!
      ierror = 0
!
      if (nprev == 0 .and. &
          .not. Associated (send_info%virtual(ialloc, ipart)%vector) ) then

         Allocate (send_info%virtual(ialloc, ipart)%vector(nloc), &
                   STAT = ierror)
         if ( ierror > 0 ) then
            ierrp (1) = ierror
            ierrp (2) = nloc

            ierror = PRISM_Error_Alloc
            call psmile_error ( ierror, 'send_info%virtual()%vector', &
                                ierrp, 2, __FILE__, __LINE__ )
            return

         endif
      end if
!
      virtual => send_info%virtual(ialloc, ipart)%vector
!
      n = nprev

      if (opt == 0) then
!cdir vector
          do i = ibeg, len
          if (abs(found (i)) == 1) then

             n = n + 1
             virtual (n) = virtual_cell (i)

#ifdef DEBUGX
             if (n == 1) then
                print *, 'store_source_virt_3d: n, i, virtual', &
                         n, i, virtual (n), found (i)
             endif
#endif
          endif
          end do
!
      else
!
!cdir vector
          do i = ibeg, len
          if (found (i) == opt) then

             n = n + 1
             virtual (n) = virtual_cell (i)

#ifdef DEBUGX
             if (n == 1) then
                print *, 'store_source_virt_3d: n', n, ', i', i, &
                         ', virtual', virtual(n), 'found', found (i)
             endif
#endif
          endif
          end do
      endif

#ifdef PRISM_ASSERTION
      if (nloc < n) then
         print *, "nloc, n", nloc, n
         call psmile_assert ( __FILE__, __LINE__, "nloc < n")
      endif
#endif
!
!===> All done
!
#ifdef VERBOSE
      print 9980, trim(ch_id), ierror

      call psmile_flushstd
#endif /* VERBOSE */
!
!  Formats:
!
#ifdef VERBOSE

9990 format (1x, a, ': psmile_store_source_virt_3d: opt ', i2, &
             '; nloc, ibeg, len, nprev ', 4i8)
9980 format (1x, a, ': psmile_store_source_virt_3d: eof ierror =', i3)

#endif /* VERBOSE */

      end subroutine PSMILe_store_source_virt_3d