psmile_transform_coords.F90

Go to the documentation of this file.

!-----------------------------------------------------------------------
! Copyright 2006-2010, NEC Europe Ltd., London, UK.
! All rights reserved. Use is subject to OASIS4 license terms.
!-----------------------------------------------------------------------
!BOP
!
! !ROUTINE: PSMILe_Transform_coords
!
! !INTERFACE:

      subroutine psmile_transform_coords (comp_info, search, ierror)
!
! !USES:
!
      use prism_constants
      use psmile_common, only : enddef_comp, enddef_search, &
                                len_cvs_string, ch_id,      &
                                MPI_REAL, MPI_DOUBLE_PRECISION
      use psmile, only : all_comp_infos
      use psmile_grid, dummy_interface => psmile_transform_coords

      implicit none
!
! !INPUT PARAMETERS:
!
      Type (Enddef_comp), Intent (In)     :: comp_info
!
!     Infos on the component (located on the actual process)
!
! !INPUT/OUTPUT PARAMETERS:
!
      Type (Enddef_search), Intent (InOut) :: search

!     Data on the points to be searched
!
! !OUTPUT PARAMETERS:
!
      integer, Intent (Out)               :: ierror

!     Returns the error code of PSMILe_Transform_coords;
!             ierror = 0 : No error
!             ierror > 0 : Severe error
!
! !LOCAL VARIABLES
!
!
!     ... for partitions
!
      Integer                      :: ipart
!
!     ... for grids
!
! igrid   = Grid index of local comp_info in which the donor cells
!           should be searched.
! 
      Integer                      :: igrid, sgrid
!
!     ... for transformations of search coordinates
!
      Integer                      :: tr_code, tr_code_search
!
! !DESCRIPTION:
!
! Subroutine "PSMILe_Transform_coords" transforms the coordinates to
! be seached into the coordinate space of the source grid.
!
!
! !REVISION HISTORY:
!
!   Date      Programmer   Description
! ----------  ----------   -----------
! 03.07.21    H. Ritzdorf  created
!
!EOP
!----------------------------------------------------------------------
!
! $Id: psmile_transform_coords.F90 2787 2010-11-29 16:51:32Z hanke $
! $Author: hanke $
!
   Character(len=len_cvs_string), save :: mycvs = 
       '$Id: psmile_transform_coords.F90 2787 2010-11-29 16:51:32Z hanke $'
!
!----------------------------------------------------------------------
!
!  Initialization
!
#ifdef VERBOSE
      print 9990, trim(ch_id), search%msg_intersections%src_comp_id

      call psmile_flushstd
#endif /* VERBOSE */

      ierror = 0

      do ipart = 1, search%npart

         igrid = search%msg_intersections%intersections(ipart)%src_all_extents_grid_id
         sgrid = search%msg_intersections%intersections(ipart)%tgt_all_extents_grid_id
!
!===> Transform locations to be searched
!     Is required only once per method.
!
         tr_code        =                 comp_info%all_extent_infos(3, igrid)
         tr_code_search = &
            all_comp_infos(search%msg_intersections%all_comp_infos_comp_idx)%all_extent_infos(3, sgrid)

#ifdef DEBUG
         print *, trim(ch_id), ': igrid, sgrid, codes,',  &
                                  igrid, sgrid, tr_code, tr_code_search
         print *, trim(ch_id), ': range',  &
                search%msg_intersections%intersections(ipart)%intersection
#endif

         if (tr_code /= tr_code_search) then
            select case (search%datatype)
               case (MPI_DOUBLE_PRECISION)
                  call psmile_transform_coords_db_re (tr_code_to=tr_code, &
                     tr_code_from=tr_code_search, &
                     coords_data_dble=search%search_dble(1:ndim_3d, ipart), &
                     coords_size=search%dims(1:ndim_3d, ipart), &
                     datatype=search%datatype, ierror=ierror)
               case (MPI_REAL)
                  call psmile_transform_coords_db_re (tr_code_to=tr_code, &
                     tr_code_from=tr_code_search, &
                     coords_data_real=search%search_real(1:ndim_3d, ipart), &
                     coords_size=search%dims(1:ndim_3d, ipart), &
                     datatype=search%datatype, ierror=ierror)
               case default
                  ierror = ierror + 1
            end select

            if (ierror > 0) return

!        else

!        Transformation is not required since the source grid and the
!        destination grid use the same coordinate space

         endif
      end do
!
!===> All done
!
#ifdef VERBOSE
      print 9980, trim(ch_id), search%msg_intersections%src_comp_id, ierror

      call psmile_flushstd
#endif /* VERBOSE */
!
!  Formats:
!
#ifdef VERBOSE

9990 format (1x, a, ': psmile_transform_coords: comp_id =', i3)
9980 format (1x, a, ': psmile_transform_coords: comp_id =', i3, &
                    '; eof ierror =', i4)

#endif /* VERBOSE */

      end subroutine PSMILe_Transform_coords