psmile_trs_get_dble.F90

Go to the documentation of this file.

!------------------------------------------------------------------------
! Copyright 2006-2010, CERFACS, Toulouse, France.
! All rights reserved. Use is subject to OASIS4 license terms.
!-----------------------------------------------------------------------
!BOP
!
! !ROUTINE: PSMILe_Trs_get_dble
!
! !INTERFACE:

subroutine psmile_trs_get_dble(id_transient_in_id, &
                               id_epio_id,         &
                               id_trans_rank,      &
                               id_epio_field_size, &
                               dda_field,          &
                               nbr_fields,         &
                               id_err)
!
! !USES:
!
  use PRISM_constants
  USE PSMILe, dummy_interface => PSMILe_Trs_get_dble

  IMPLICIT NONE
!
! !INPUT PARAMETERS:
!
! involved field
  INTEGER, INTENT (In)                     :: id_transient_in_id

! epio for this partition field
  INTEGER, INTENT (In)                     :: id_epio_id
  INTEGER, INTENT (In)                     :: id_trans_rank

! size of the field
  INTEGER, INTENT (In)                     :: id_epio_field_size

! source field to interpolate
  DOUBLE PRECISION, DIMENSION(id_epio_field_size), INTENT (Out) :: dda_field

! nbr of bundle components
  INTEGER, INTENT (In)                     :: nbr_fields

!
! !OUTPUT PARAMETERS:
!
  INTEGER, INTENT (Out)                    :: id_err   ! error value

! !DESCRIPTION:
! Subroutine "PSMILe_Trs_get_dble" gets the field from the transformer.
!
! !REVISION HISTORY:
!   Date      Programmer   Description
! ----------  ----------   -----------
! 28/01/2003  D. Declat    Creation
! 01/12/2003  D. Declat    Adapted to type int, real, dble
!
!EOP
!----------------------------------------------------------------------
! $Id: psmile_trs_get_dble.F90 2325 2010-04-21 15:00:07Z valcke $
! $Author: valcke $
!----------------------------------------------------------------------
!
! 0. Local declarations
!
  CHARACTER(LEN=len_cvs_string), SAVE  :: mycvs = '$Id: psmile_trs_get_dble.F90 2325 2010-04-21 15:00:07Z valcke $'

  INTEGER, DIMENSION(PSMILe_trans_Header_length) :: ila_args 
  INTEGER                :: il_status(MPI_STATUS_SIZE)

!
!----------------------------------------------------------------------
!
#ifdef VERBOSE
      print *, trim(ch_id), ': PSMILe_Trs_get_dble: start'

      call psmile_flushstd
#endif /* VERBOSE */

!
! 1. Set the header message
!
! 1.1. Initialize the contents to 999999

  ila_args = 999999

! 1.2. Content : action, global rank, field_id, comp_id, local rank

  ila_args(1) = PSMILe_trans_Get
  ila_args(2) = global_rank
  ila_args(3) = id_transient_in_id
  ila_args(4) = id_epio_id
  ila_args(5) = PRISM_DOUBLE_PRECISION
  ila_args(6) = nbr_fields

!
! 2. Send the header message to the transformer
!
  call psmile_trs_inform(ila_args, id_trans_rank, id_err)

!
! 3. Recv the field
!
  CALL MPI_Recv(dda_field, id_epio_field_size, MPI_DOUBLE_PRECISION, &
     id_trans_rank, 0177, comm_trans, il_status, id_err)
!
#ifdef VERBOSE
      print *, trim(ch_id), ': PSMILe_Trs_get_dble: eof ierror =', &
               id_err
      call psmile_flushstd

#endif /* VERBOSE */
  
END SUBROUTINE PSMILe_Trs_get_dble