get_grids_details.F90

Go to the documentation of this file.

!------------------------------------------------------------------------
! Copyright 2006-2010, CERFACS, Toulouse, France.
! All rights reserved. Use is subject to license terms.
!======================================================================
!
  SUBROUTINE get_grids_details ( id_XML_doc,         &
                                 id_nb_grids,        &
                                 cda_app_name,       &
                                 cda_comp_name,      &
                                 sda_smioc_grids,    &
                                 id_error )     

! !DESCRIPTION
! This routines gives extracts the grids informations for all the grids
! of one smioc
!
!----------------------------------------------------------------------
!
    USE PSMILe_smioc
    IMPLICIT NONE
!
! !REVISED HISTORY
!   Date        Programmer     Description
! ----------    ----------     -----------
! 20/10/2003    S. Valcke      Creation
! 30/12/2003    D. Declat      Implemented as a module
! 30/10/2010   JM Epitalon     Adapted to CIM (Common Info Model)
!
!EOP
!----------------------------------------------------------------------
! $Id: psmile_smioc.F90 1793 2008-11-25 14:58:31Z valcke $
! $Author: valcke $
!----------------------------------------------------------------------
!
! 0. Declaration
!
! handle of XML content of the smioc file
    INTEGER, INTENT(In) :: id_XML_doc

! number of grids for the component
    INTEGER, INTENT(In) :: id_nb_grids  

! Names of application and component
    CHARACTER(len=*), INTENT(In)  :: cda_app_name
    CHARACTER(len=*), INTENT(In)  :: cda_comp_name

! grids structure for the component
    TYPE (smioc_grid), DIMENSION(id_nb_grids), INTENT(Out) :: sda_smioc_grids 
!
! returned error code
   INTEGER, INTENT(Out) :: id_error  
!
#if CIM
    INTEGER :: sasa_c_get_element_7th_level_c
    CHARACTER(len=max_name+44) :: cla_model_appli
    CHARACTER(len=max_name+44) :: cla_model_comp
#else
    INTEGER :: sasa_c_convert_char2int
    INTEGER :: sasa_c_get_attri_2nd_level, sasa_c_get_attri_3rd_level
    INTEGER :: sasa_c_get_attri_4th_level, sasa_c_get_attri_5th_level
    INTEGER :: sasa_c_get_element_5th_level_i
    INTEGER :: sasa_c_get_element_5th_level_d
    INTEGER :: sasa_c_get_number_3rd_level
#endif
!
    CHARACTER(LEN=max_name) :: cla_char
    INTEGER :: ib, ib_bis, ib_ind, il_index
!
    INTEGER :: il_length
!
!-----------------------------------------------------------------------
!
#if CIM
    ! Prepare two predicates for the search in the XML documents :
    !   based on application and model shortNames
    cla_model_appli = 'modelComponent[normalize-space(shortName)="'//TRIM(cda_app_name)//'"]'
    cla_model_comp  = 'modelComponent[normalize-space(shortName)="'//TRIM(cda_comp_name)//'"]'
#endif
        
    DO ib =1, id_nb_grids

#if CIM
    ! Configuration data are in one CIM file
    ! --------------------------------------
     
    ! get the grid local name
    sda_smioc_grids(ib)%cg_grid_name = ' '
    id_error = &
        sasa_c_get_element_7th_level_c (id_XML_doc, &
        "simulationComposite/child/simulationRun/model/modelComponent", 0,  &
        "childComponent", 0, TRIM(cla_model_appli), 0, "childComponent", 0, &
        TRIM(cla_model_comp), 0, "grid", ib, "reference", 0, "name", 0,     &
        sda_smioc_grids(ib)%cg_grid_name, il_length )

      ! TEMPORARY        
      ! Set the "periodic" attribute for first dimension equaly for all grids
      ! for test with Toyoa4 example model
      sda_smioc_grids(ib)%iga_periodic(1) = .true.

#else
    ! Configuration data are in a SMIOC file
    ! --------------------------------------
    
      ! get the grid local name
      id_error = &
         sasa_c_get_attri_2nd_level (id_XML_doc,          &
         'component', 0, 'grid', ib, 'local_name',   &
         sda_smioc_grids(ib)%cg_grid_name, il_length)

      ! get the indexing_dimension elements
      id_error = &
         sasa_c_get_number_3rd_level(id_XML_doc,               &
         'component', 0, 'grid', ib, 'indexing_dimension',&
         ib_ind)
      
      IF (ib_ind > 0) THEN
          DO ib_bis = 1, ib_ind
            id_error = &
               sasa_c_get_attri_3rd_level (id_XML_doc,                &
               'component', 0, 'grid', ib, 'indexing_dimension', &
               ib_bis, 'index', cla_char, il_length)

            IF (id_error .EQ. 0) THEN
                READ (cla_char, *) il_index
            ELSE
                PRINT *, '****************************************************'
                PRINT *, 'Problem in reading index in indexing_dimension      '
                PRINT *, '****************************************************'
                CALL PSMILe_Flushstd
                CALL MPI_Abort(MPI_COMM_WORLD, 1, id_error)
            ENDIF

            id_error = &
               sasa_c_get_attri_3rd_level (id_XML_doc,                &
               'component', 0, 'grid', ib, 'indexing_dimension', &
               ib_bis, 'periodic', cla_char, il_length)
            IF (id_error .EQ. 0) THEN
                sda_smioc_grids(ib)%iga_periodic(il_index) =               &
                   sasa_c_convert_char2int(cla_char(1:il_length))
            ENDIF
        
          END DO
      ENDIF
#endif
    
    END DO

  END SUBROUTINE get_grids_details

!
!======================================================================