get_smioc_numbers.F90

Go to the documentation of this file.

!------------------------------------------------------------------------
! Copyright 2006-2010, CERFACS, Toulouse, France.
! All rights reserved. Use is subject to license terms.
!------------------------------------------------------------------------
!BOP
!
  SUBROUTINE get_smioc_numbers ( id_XML_doc,         &
                                 id_nb_unitsets,     &
                                 id_nb_grids,        &
                                 id_nb_transi,       &
                                 id_nb_persis,       &
                                 id_comp,            &
                                 cda_app_name,       &
                                 cda_comp_name,      &
                                 ld_userdef_details,   &
                                 id_error )

! !DESCRIPTION
! This routine gives the numbers of Fortran unit sets, grids, transi and persis
! for one XML smioc
!
!----------------------------------------------------------------------------------

    USE PSMILe_smioc
    IMPLICIT NONE
!
!EOP
!----------------------------------------------------------------------
! $Id: psmile_smioc.F90 1793 2008-11-25 14:58:31Z valcke $
! $Author: valcke $
!----------------------------------------------------------------------
!
! 0. Declaration
!
! handle of XML content of the smioc file
    INTEGER, INTENT(In) :: id_XML_doc

! number of Fortran unit sets for the component
    INTEGER, INTENT(Out) :: id_nb_unitsets

! number of grids for the component
    INTEGER, INTENT(Out) :: id_nb_grids       

! number of transi variables for the component
    INTEGER, INTENT(Out) :: id_nb_transi  

! number of persis variables for the component!
    INTEGER, INTENT(Out) :: id_nb_persis

! id number of component
    INTEGER, INTENT(In)  :: id_comp

! Names of application and component
    CHARACTER(len=*), INTENT(In)  :: cda_app_name
    CHARACTER(len=*), INTENT(In)  :: cda_comp_name

! logical flag first pass / second pass
    LOGICAL, INTENT(In)  :: ld_userdef_details

! returned error code
    INTEGER, INTENT(Out) :: id_error 
!
#if CIM
    INTEGER :: sasa_c_get_number_10th_level, sasa_c_get_number_11th_level
    CHARACTER(len=max_name+44) :: cla_model_appli
    CHARACTER(len=max_name+44) :: cla_model_comp
#else
    INTEGER :: sasa_c_get_number_2nd_level, sasa_c_get_number_3rd_level
    INTEGER :: sasa_c_get_number_1st_level, il_nbpc
#endif
    
!
!----------------------------------------------------------------------
!
#if CIM
    ! Configuration data are in one CIM file
    ! --------------------------------------

    ! Prepare two predicates for the search in the XML documents :
    !   based on application and model shortNames
    cla_model_appli = 'modelComponent[normalize-space(shortName)="'//TRIM(cda_app_name)//'"]'
    cla_model_comp  = 'modelComponent[normalize-space(shortName)="'//TRIM(cda_comp_name)//'"]'

    id_error = &
        sasa_c_get_number_10th_level (id_XML_doc, &
        "simulationComposite", 0, "child", 0, "simulationRun", 0, "model", 0, "modelComponent", 0,  &
        "childComponent", 0, TRIM(cla_model_appli), 0, "childComponent", 0, &
        TRIM(cla_model_comp), 0, "grid", id_nb_grids)
        
    id_error = &
        sasa_c_get_number_11th_level (id_XML_doc, &
        "simulationComposite", 0, "child", 0, "simulationRun", 0, "model", 0, "modelComponent", 0,  &
        "childComponent", 0, TRIM(cla_model_appli), 0, "childComponent", 0, &
        TRIM(cla_model_comp), 0, "componentProperties", 0, "componentProperty", id_nb_transi)
    
    id_nb_unitsets = 0
    id_nb_persis  = 0
    
#else
    ! Configuration data are in a SMIOC file
    ! --------------------------------------
    
    il_nbpc = 0
    id_error = &
       sasa_c_get_number_1st_level(id_XML_doc,    &
       'prismcomponent', il_nbpc)
    IF (il_nbpc == 1) THEN
        PRINT *, '******************************************************'
        PRINT *, 'Since SVN revision 2633, "prismcomponent" must be '
        PRINT *, 'replaced by "component" in all SMIOC XML file'
        PRINT *, '******************************************************'
        CALL PSMILe_Flushstd
        CALL MPI_Abort(MPI_COMM_WORLD, 1, id_error)
    ENDIF

    id_error = &
       sasa_c_get_number_3rd_level(id_XML_doc, 'component', 0,   &
       'code', 0, 'Fortran_units', id_nb_unitsets)
    print *,' get_smioc_numbers id_error units = ',id_error

    id_error = &
       sasa_c_get_number_2nd_level(id_XML_doc,    &
       'component', 0, 'grid', id_nb_grids)
    print *,' get_smioc_numbers id_error grids = ',id_error

    id_error = &
       sasa_c_get_number_2nd_level(id_XML_doc,    &
       'component', 0, 'transient', id_nb_transi)
    print *,' get_smioc_numbers id_error transi = ',id_error

    id_error = &
       sasa_c_get_number_2nd_level(id_XML_doc,    &
       'component', 0, 'persistent', id_nb_persis)
    print *,' get_smioc_numbers id_error persist = ',id_error
#endif

! If called by driver, we must include "udef transients" of current component in id_nb_transi
!                      and in id_nb_grids (one implicit "gridless" grid per udef transient)
!
    if ( ld_userdef_details ) then
         id_nb_transi = id_nb_transi + iga_comp_nb_udef(id_comp)
         id_nb_grids  = id_nb_grids  + iga_comp_nb_udef(id_comp)
    endif
!
  END SUBROUTINE get_smioc_numbers
!
!======================================================================